Spock testing a ResultSet in Groovy - unit-testing

Question

Here is what I have so far:
def "If there are results then return true otherwise return false"() {
given:
ResultSet resultSet = Mock()
expect:
resultSet.next()
}
I am trying to test a boolean method checkIfRowExists(int id, int foreignKey) in class CheckActuateProjectSetServiceImpl. It returns true if row exists and false otherwise.
How would I go about solving this?
public boolean checkIfRowExists(int id, int foreignKey){
Resultset resultSet = checkIfRowExistsResultSet(id, foreignKey)
return false;
}
The above method doesn't have the correct implementation as of yet because I'm trying to write the test first before I implement the solution.
Thanks

Answer 1

If I were on your place I would do the next TDD steps.
Start with a test for one test case only:
def "If there not are results then return false"() {
given:
def service = new CheckActuateProjectSetServiceImpl()
expect:
!service.checkIfRowExists(1, 2)
}
Implement the method to satisfy the test:
boolean checkIfRowExists(int id, int foreignKey) {
return false;
}
Add new test for case when there are some result:
def "If there are results then return true"() {
given:
def service = new CheckActuateProjectSetServiceImpl()
expect:
service.checkIfRowExists(1, 2)
}
Now we are forced to implement our method. The method will do a DB query and check the actual result set for emptiness. Because the DB query is out of unit test scope we extract it to a separate method and will override it in the test later:
boolean checkIfRowExists(int id, int foreignKey) throws SQLException {
ResultSet resultSet = getResultSet(id, foreignKey);
return resultSet.next();
}
ResultSet getResultSet(int id, int foreignKey) {
return null; // TODO should be implemented
}
Now our test is failed with NullPointerException because getResultSet() returns null. Lets return a mocked ResultSet which returns true on next() call:
def "If there are results then return true"() {
given:
ResultSet mockedResultSet = Mock(ResultSet)
mockedResultSet.next() >> true
def service = new CheckActuateProjectSetServiceImpl() {
#Override
def ResultSet getResultSet(int id, int foreignKey) {
return mockedResultSet;
}
}
expect:
service.checkIfRowExists(1, 2)
}
The test is green now.
The first test is to be fixed as well, mock to return false on next() call:
def "If there not are results then return false"() {
given:
ResultSet mockedResultSet = Mock(ResultSet)
mockedResultSet.next() >> false
def service = new CheckActuateProjectSetServiceImpl() {
#Override
def ResultSet getResultSet(int id, int foreignKey) {
return mockedResultSet;
}
}
expect:
!service.checkIfRowExists(1, 2)
}
Hope it will help. These steps are just an orientation to move forward in TDD style. Sure things your reality is different and may require something more specific that I proposed above.