awk if-else and variable reassignment - if-statement

Question

I have a text file consisting of xyz coordinates, each defining a particular depth contour of a slope.
All of these lines are stored in one file, with each contour separated by ">"
The file looks like:
>
x1 y1 z1
x2 y2 z2
>
x3 y3 z3
...
The file is huge and unwieldy and I want to print out the 7th point along each contour and pipe it into a tab delimited new file.
My code looks like this:
awk -v OFS='\t' -v count=1 '{if ($1 == ">") {count/=count}; else if (count%7 == 0) {{count+=1} print $0}; else {count+=1}}' infile > outfile
I keep getting an error message that says
awk: syntax error at source line 1
context is
{if ($1 == ">") {count/=count}; >>> else <<< if (count%7 == 0) {{count+=1}; print $0}; else {count+=1}}
awk: illegal statement at source line 1
I've spent a while checking my syntax and bracketing and it seems ok, I just might be missing something with the variable reassignment?

Answer 1

Your syntax is very close; just a bit off. Looks like there may be some confusion between the curly braces { } and the normal parentheses. As you play around more with awk the difference should become much clearer.
Before I get to your particular syntax issue, note that a simpler approach can solve the same problem:
awk -v OFS='\t' '$1 == ">" { count = 1; next } !(count++ % 7)' file
A multiline version your corrected code would be:
{
if ($1 == ">") {
count = 1
}
else
if (count % 7 == 0) {
count += 1
print $0
}
else
count += 1
}
As long as a statement is on its own line, you don't need a semicolon. But note that to make it a one-liner, you will need one as shown:
{ if ($1 == ">") { count = 1 } else if (count % 7 == 0) { count += 1; print $0 } else count += 1 }