cmake boost find_depedency Config - c++

Question

I ran into this issue when trying to generate a Config for my build and the consume the target upstream while using different boost COMPONENTS. It feels like I'm missing something or maybe even misunderstood how I'm supposed to be using the Config.cmake file to generate targets for an upstream package. That you have to specify find_dependency again seems...off.
In the below SomeProjectConfig.cmake file I have to check whether an upstream package did load the necessary targets for SomeProject to work, if it didn't I need to call find boost with the necessary components again.
# SomeProjectConfig.cmake.in
# Avoid repeatedly including the targets
if(NOT TARGET SomeProject::SomeProject)
# Provide path for package module scripts, CMAKE_CURRENT_LIST_DIR is the
# directory of the currently executing cmake file.
list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
include(CMakeFindDependencyMacro)
# --------------------------------------------------------------------------
# Boost
# The way I choose to go about it is to simply check if the dependency boost
# targets are defined - if they are we don't have to do anything and just let
# everything pass through. However if they are missing we need to set
# Boost_FOUND back to FALSE so it'll resolve the dependencies...
list(APPEND SomeProject_Boost_COMPONENTS system thread)
foreach(_comp ${SomeProject_Boost_COMPONENTS})
if(NOT TARGET Boost::${_comp})
set(Boost_FOUND 0)
break()
endif()
endforeach()
# Additionally we record the BOOST_ROOT - but we try to respect the upstream
# package if specifies it.
if(NOT BOOST_ROOT)
set(BOOST_ROOT "#BOOST_ROOT#"
endif()
# We want to handle this quietly, upstream packages might want to include more
# componentes and if we ask for components first Boost will handle it as if
# we've already done all the necessary work.
find_dependency(Boost 1.55 QUIET REQUIRED COMPONENTS ${SomeProject_Boost_COMPONENTS})
# We can never leave without setting Boost_FOUND to FALSE - if the upstream
# package has find_package(Boost) after find_package(SomeProject) it'll
# break if Boost_FOUND is TRUE
set(Boost_FOUND 0)
# // Boost
# --------------------------------------------------------------------------
find_dependency(SomeOtherDependency 1.0 QUIET REQUIRED)
include("${CMAKE_CURRENT_LIST_DIR}/SomeProjectTargets.cmake")
# Clean up module path after we're done
list(REMOVE_AT CMAKE_MODULE_PATH -1)
endif()
The problem with the above as I see it is that we're leaving Boost_FOUND set to 0 and from my point of view it's really hard to control, it also feels like I'm actually not understanding the Config package process correctly.
# CMakeLists.txt upstream
find_package(Boost 1.55 REQUIRED COMPONENTS filesystem)
set(SomePackage_DIR "/path/to/Config/location")
find_package(SomePackage REQUIRED)
add_library(UpstreamTarget SHARED ${sources})
target_link_libraries(UpstreamTarget PUBLIC Boost::filesystem SomeProject::SomeProject)
The above will work, but it leaves me with a bad itch - it feels like I'm doing it wrong.

Answer 1

Turns out it was my use of the find_dependency macro, replacing it with find_package gave me the correct results without workarounds.
If we dive into the CMakeFindDependencyMacro.cmake it becomes quite clear what the issue is.
macro(find_dependency dep)
if (NOT ${dep}_FOUND)
...
If the package is already found it will stop the execution right there and won't append the additional components. Meaning you could have the find_package(SomePackage) call before any additional find_package(Boost) upstream, but not the other way around.
I don't think this is a problem for isolated packages but once you have components that you might need to append to an already existing target find_dependency seems to break due to the if statement. Judging from another answer in regards to find_dependency it looks like it would mostly be for diagnostic messages telling the user that the problem comes from a *Config.cmake file than anything else.
for completeness here's a working example of the config file where I removed the workarounds:
# SomeProjectConfig.cmake.in
# Avoid repeatedly including the targets
if(NOT TARGET SomeProject::SomeProject)
# Provide path for package module scripts, CMAKE_CURRENT_LIST_DIR is the
# directory of the currently executing cmake file.
list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
include(CMakeFindDependencyMacro)
# Additionally we record the BOOST_ROOT - but we try to respect the upstream
# package if it specifies it.
if(NOT BOOST_ROOT)
set(BOOST_ROOT "#BOOST_ROOT#"
endif()
find_package(Boost 1.55 QUIET REQUIRED COMPONENTS system thread)
find_dependency(SomeOtherDependency 1.0 QUIET REQUIRED)
include("${CMAKE_CURRENT_LIST_DIR}/SomeProjectTargets.cmake")
# Clean up module path after we're done
list(REMOVE_AT CMAKE_MODULE_PATH -1)
endif()