Writing the Ackermann function in a SAS data step - sas

Question

In my quest to understand recursive programming in SAS, I have tried, unsuccessfully many times, to write a version of a two-argument Ackermann function.
The function states that:
I was only going to calculate m & n for values ranging from 0 - 3, as values of m >= 4 cause the returned values to become large very rapidly.
I was shooting for a relatively simple output; something like:
Ack(0,0) = 1
Ack(0,1) = 2
Ack(0,2) = 3
Ack(0,3) = 4
Ack(1,0) = 2
Ack(1,1) = 3
And so on to Ack(3,3) = 61
I was unable to find any reference online to someone doing this in SAS. So, if someone could help me with this, I would really appreciate it!
Thanks!

Answer 1

proc fcmp implementation:
/* Define */
proc fcmp outlib=work.funcs.math;
function ackerman(m, n);
if m = 0 then return(n + 1);
else if n = 0 then return(ackerman(m - 1, 1));
else return(ackerman(m - 1, ackerman(m, n - 1)));
endsub;
run;
quit;
/*Test*/
option cmplib = work.funcs;
proc fcmp;
out = ackerman(3,2);
put "Testing Function Call";
put "ackerman(3,2) returns:" out;
quit;

Answer 2

Here is a SAS/AF class implementation
sasuser.examples.ackermanclass.scl
Class Ackerman extends sashelp.fsp.object.class;
compute: public method
m: num
n: num
return = num;
if m=0 then return n+1;
if m > 0 then do;
if n = 0 then return compute ( m-1, 1 );
if n > 0 then return compute ( m-1, compute ( m, n-1 ) );
throw _new_ SASHelp.Classes.SCLException ("Ackerman compute, invalid args: n=" || cats(n));
end;
throw _new_ SASHelp.Classes.SCLException ("Ackerman compute, invalid args: m=" || cats(m));
endmethod;
EndClass;
sasuser.examples.ackermantest.scl
init:
declare sasuser.examples.ackerman.class ackerman
= _new_ sasuser.examples.ackerman.class();
do m = 0 to 3;
do n = 0 to 3;
put m= n= 'result=' ackerman.compute(m,n);
end;
end;
return;
Test with AFA C=sasuser.examples.ackermantest.scl
m=0 n=0 result=1
m=0 n=1 result=2
m=0 n=2 result=3
m=0 n=3 result=4
m=1 n=0 result=2
m=1 n=1 result=3
m=1 n=2 result=4
m=1 n=3 result=5
m=2 n=0 result=3
m=2 n=1 result=5
m=2 n=2 result=7
m=2 n=3 result=9
m=3 n=0 result=5
m=3 n=1 result=13
m=3 n=2 result=29
m=3 n=3 result=61

Answer 3

Here is Proc DS2 example that uses recursion:
proc ds2;
data _null_;
method ackerman(int m, int n) returns int;
if m=0 then return n+1;
if m > 0 then do;
if n = 0 then return ackerman ( m-1, 1 );
if n > 0 then return ackerman ( m-1, ackerman ( m, n-1 ) );
return -1;
end;
return -1;
end;
method init();
declare int m n result;
do m = 0 to 3;
do n = 0 to 3;
result = ackerman(m,n);
put m= n= result=;
end;
end;
end;
enddata;
run;
quit;

Answer 4

It is difficult to do recursion in normal SAS code. But it is easy in macro code.
%macro a(m,n);
%if %sysfunc(verify(&m.&n,0123456789)) %then %do;
%put WARNING: Invalid input to macro &sysmacroname.. Use only non-negative integers.;
.
%end;
%else %if (&m=0) %then %eval(&n+1);
%else %if (&n=0) %then %a(%eval(&m-1),1);
%else %a(%eval(&m-1),%a(&m,%eval(&n-1)));
%mend a;
If you must use it with the values of dataset variables then you might consider using the resolve() function.
data testa;
do i=0 to 3; do j=0 to 3;
a=input(resolve(cats('%a(',i,',',j,')')),32.);
output;
end;end;
run;
proc print; run;
Results
Obs i j a
1 0 0 1
2 0 1 2
3 0 2 3
4 0 3 4
5 1 0 2
6 1 1 3
7 1 2 4
8 1 3 5
9 2 0 3
10 2 1 5
11 2 2 7
12 2 3 9
13 3 0 5
14 3 1 13
15 3 2 29
16 3 3 61
Of course if you are only ever going to use arguments from 0 to 3 then perhaps you just need to use an array lookup instead.
data testb;
array _a(0:3,0:3) _temporary_
(1 2 3 4
2 3 4 5
3 5 7 9
5 13 29 61
);
do i=0 to 3; do j=0 to 3; a=_a(i,j); output; end; end;
run;