SAS - Using If-then-do in macro - sas

Question

I'm making a macro to pull tables from a database, then export some of those tables using proc export. I'm doing this by using an if-then-do statement to check if the macro variable equals a string, and if it does then that table gets exported. Here's my code:
%MACRO query(x);
proc sql;
connect using conn;
create table &x. as select * from connection to conn
(select *
from db.&x.);
disconnect from conn;
quit;
%if &x. = "AddressCategory" %then
%do;
proc export data = &x. outfile="C:\path\&x..txt" dbms=dlm replace; delimiter="|";
run;
%end;
%mend query;
%query(AddressCategory);
This produces a dataset named AddressCategory, but the export doesn't work. any ideas? Thanks!

Answer 1

then export some of those tables
Within the macro you likely don't want to check for the item to export by name. If you do, the macro will grow to contain a large number of ifs checking which argument is appropriate for export.
A better macro would have an additional export= parameter that defaults to 0, and the callee sets it to 1 for the data sets to be exported
%MACRO fetcher (
remoteLibref=conn,
remoteSchema=db,
object=,
outlib=work,
out=&object,
export=0,
outpath=C:\exports\&remoteSchema,
outname=&object
);
proc sql;
connect using &remoteLibref;
create table &outlib..&out as select * from connection to &remoteLibref
( select *
from &remoteSchema..&object
);
disconnect from &remoteLibref;
quit;
%if &export %then %do;
proc export
dbms=dlm
data=&outlib..&out.
replace outfile="&outpath.\&object..txt"
;
delimiter="|";
run;
%end;
%mend fetcher;
The invoke it for your various remote objects, specifying explicitly the ones to export
libname conn sqlserver … connection string … ;
%fetcher(object=AddressCategory, export=1)
%fetcher(object=AddressBook)
%fetcher(object=PreferenceCategory, export=1)
%fetcher(object=PreferenceItems)
%fetcher(object=PreferenceProperties)
%fetcher(object=Payouts, export=1)
%fetcher(object=Payouts, RemoteSchema=DBX, export=1, outname=hidden-payouts)