How do I conditionally create an array of class parameters from an array in D? - d

Question

Say I have an associative array that contains a bunch of class instances. I want to find an idiomatic D way of creating an array (or range) containing properties that belong to class instances in the array that mean some boolean criteria.
See the example below, in this case I would want to create an array or range containing the age of students that are in the fifth grade.
I know how to do this with loops and conditionals, but if there is a built-in function or idiomatic way of doing this in D, that would be super helpful.
import std.stdio;
class Student {
private:
uint grade;
uint age;
uint year;
public:
this(uint g, uint a, uint y) {
grade = g;
age = a;
year = y;
}
uint getAge() {
return age;
}
uint getGrade() {
return grade;
}
uint getYear() {
return year;
}
}
void main() {
Student[uint] classroom;
Student s1 = new Student(1, 5, 2);
Student s2 = new Student(2, 6, 1);
Student s3 = new Student(3, 7, 2);
Student s4 = new Student(4, 8, 9);
classroom[1] = s1;
classroom[2] = s1;
classroom[3] = s1;
classroom[4] = s1;
// I want to generate an array or range here containing the age of students who are in the X'th grade
}

Answer 1

All you need is little bit of functional programming with the help of the std.algorithm module:
import std.stdio;
import std.algorithm, std.array;
class Student {
private:
uint grade;
uint age;
uint year;
public:
this(uint g, uint a, uint y) {
grade = g;
age = a;
year = y;
}
uint getAge() {
return age;
}
uint getGrade() {
return grade;
}
uint getYear() {
return year;
}
}
void main() {
Student[uint] classroom;
Student s1 = new Student(1, 5, 2);
Student s2 = new Student(2, 6, 1);
Student s3 = new Student(3, 7, 2);
Student s4 = new Student(4, 8, 9);
classroom[1] = s1;
classroom[2] = s2;
classroom[3] = s3;
classroom[4] = s4;
classroom[5] = new Student(3, 8, 3);
// I want to generate an array or range here containing the age of students who are in the X'th grade
uint grd = 3;
auto ages = classroom.values
.filter!(student => student.getGrade() == grd)
.map!(student => student.getAge());
writeln(ages);
uint[] arr = ages.array; // if you need to turn the range into an array
writeln(arr); // prints the same as above
}

Answer 2

std.algorithm has your back:
import std.algorithm, std.array;
auto kids = classroom.values
.filter!(student => student.grade == 5)
.array;
If you want to do this for every grade at once, you need to sort and then chunkBy, something like:
classroom.values
.sort!((x, y) => x.grade < y.grade)
.chunkBy((x, y) => x.grade == y.grade)
Which gives you a range of [ranges of students with the same grade].