(SAS) Removing duplicates during concatenation - sas

Question

I'm using the following data step to concatenate multiple observations' values into one variable:
data Data_PreFinal;
set work.reasons;
by Number;
length Changes $4000.;
retain Changes;
if first.Number then Changes = EndoReason;
else Changes = catx(', ', Changes, EndoReason);
if last.Number then output;
run;
For example, I would like to ensure that if the dataset Reasons looks like this:
Number EndoReason
1 Bucket1
1 Bucket2
1 Bucket1
1 Bucket3
1 Bucket2
1 Bucket2
2 Bucket2
2 Bucket2
2 Bucket1
2 Bucket2
that the resulting dataset, Data_PreFinal, looks like this:
Number EndoReason
1 Bucket1, Bucket2, Bucket3
2 Bucket2, Bucket1
instead of listing out all the duplicate values in the EndoReason variable.
Any help will be greatly appreciated!
Thanks!

Answer 1

Just do a search in the current Changes string for the specific row's value and only concatenate if it doesn't already exist. The index function is the one to use and I've also modified your code slightly to use call catx instead of catx (I think it's neater in these situations).
data reasons;
input Number EndoReason $;
datalines;
1 Bucket1
1 Bucket2
1 Bucket1
1 Bucket3
1 Bucket2
1 Bucket2
2 Bucket2
2 Bucket2
2 Bucket1
2 Bucket2
;
run;
data Data_PreFinal;
set work.reasons;
by Number;
length Changes $4000.;
retain Changes;
if first.Number then call missing(Changes);
if not index(Changes,trim(EndoReason)) then call catx(', ', Changes, EndoReason);
if last.Number then output;
run;

Answer 2

Friend!, maybe it could be useful to delete duplicate observations first. For example:
data reasons;
input Number EndoReason : $30.;
datalines;
1 Bucket1
1 Bucket2
1 Bucket1
1 Bucket3
1 Bucket2
1 Bucket2
2 Bucket2
2 Bucket2
2 Bucket1
2 Bucket2
;
*Only eliminate duplicates;
proc sort data=reasons out=reasons_nodup nodup;
by Number EndoReason;
run;
data Data_PreFinal;
set work.reasons_nodup;
by Number;
length Changes $4000.;
retain Changes;
if first.Number then Changes = EndoReason;
else Changes = catx(', ', Changes, EndoReason);
if last.Number then output;
drop EndoReason;
rename Changes = EndoReason;
run;
Good luck!