XSLT for multiple conditions - xslt

Question

I have a question on XSLT. Basically I am look for ...Unique Delivery method ( Mail,Home etc) from last transaction for books having status 'In Stock' from the below xml. For example in the below example 'Mail' and 'Store Pickup' would be the result. Can somebody help me with XSLT ? Thanks in advance.
<BookCollection>
<Book>
<status>In Stock</status>
<name>The Hunt for Red October</name>
<OrderHistory>
<Order>
<transactionid>sssss</transactionid>
<date>2018-03-24</date>
<Delivery>Home</Delivery>
</Order>
<Order>
<transactionid>sssss</transactionid>
<date>2018-04-23</date>
<Delivery>Mail</Delivery>
</Order>
</Orderhistory>
</Book>
<Book>
<name>A case of need</name>
<status>Pending Stock</status>
<OrderHistory>
<Order>
<transactionid>sssss</transactionid>
<date>2018-08-24</date>
<Delivery>Home</Delivery>
</Order>
<Order>
<transactionid>sssss</transactionid>
<date>2018-02-23</date>
<Delivery>Store Pickup</Delivery>
</Order>
</Orderhistory>
</Book>
<Book>
<name>Sharp Objects</name>
<status>In Stock</status>
<OrderHistory>
<Order>
<transactionid>sssss</transactionid>
<date>2018-01-24</date>
<Delivery>Home</Delivery>
</Order>
<Order>
<transactionid>sssss</transactionid>
<date>2018-05-23</date>
<Delivery>Store Pickup</Delivery>
</Order>
</Orderhistory>
</Book>
<Book>
<name>Happy Doomsday</name>
<status>In Stock</status>
<OrderHistory>
<Order>
<transactionid>aaa</transactionid>
<date>2018-01-24</date>
<Delivery>Mail</Delivery>
</Order>
<Order>
<transactionid>bb</transactionid>
<date>2018-03-23</date>
<Delivery>Store Pickup</Delivery>
</Order>
</Orderhistory>
</Book>
.......
.........
</Book>
</BookCollection>

Answer 1

Typically if you want to find distinct items, you can view it as a grouping issue, but you only need to output one value from each group. In XSLT 1.0 you would use a technique called Muenchian Grouping, which would mean defining a key like so:
<xsl:key name="orders" match="Order" use="Delivery" />
However, you have the added complexity of getting the last Order by date. Probably the easiest option is to create a variable holding only the last Order elements for each OrderHistory
<xsl:variable name="Orders">
<xsl:for-each select="//Book[status = 'In Stock']/OrderHistory">
<xsl:for-each select="Order">
<xsl:sort select="date" order="descending" />
<xsl:if test="position() = 1">
<xsl:copy-of select="." />
</xsl:if>
</xsl:for-each>
</xsl:for-each>
</xsl:variable>
However, you need to use an extension function to convert this "Result Tree Fragment" into a node-set which you can then use the Muencjian Grouping technique on. Most like your process support EXSLT, which means adding this namespace
xmlns:exsl="http://exslt.org/common"
Then, to get the distinct values from the variable, you do this...
<xsl:for-each select="exsl:node-set($Orders)/Order[generate-id() = generate-id(key('orders', Delivery)[1])]">
Try this XSLT
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
version="1.0">
<xsl:output method="text" />
<xsl:key name="orders" match="Order" use="Delivery" />
<xsl:template match="#*|node()">
<xsl:copy>
<xsl:apply-templates select="#*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:variable name="Orders">
<xsl:for-each select="//Book[status = 'In Stock']/OrderHistory">
<xsl:for-each select="Order">
<xsl:sort select="date" order="descending" />
<xsl:if test="position() = 1">
<xsl:copy-of select="." />
</xsl:if>
</xsl:for-each>
</xsl:for-each>
</xsl:variable>
<xsl:template match="/">
<xsl:for-each select="exsl:node-set($Orders)/Order[generate-id() = generate-id(key('orders', Delivery)[1])]">
<xsl:if test="position() > 1">, </xsl:if>
<xsl:value-of select="Delivery" />
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
See this in action at http://xsltfiddle.liberty-development.net/3NzcBtu/2 (which is using Microsoft's XSLTCompiledTransform, which is XSLT 1.0).
Ideally though, you should look into upgrading to XSLT 3.0, if only to stop Martin Honnen getting bored....

Answer 2

You can do that in pure XPath 3 if the higher-order version of the sort function https://www.w3.org/TR/xpath-functions/#func-sort is supported:
distinct-values(
BookCollection/Book[status = 'In Stock']
!
sort(
OrderHistory/Order,
(),
function($order) { xs:date($order/date) }
)[last()]/Delivery
)
A complete XSLT 3 stylesheet that would work with Saxon 9.8 EE or PE or any other XSLT 3 processor supporting the higher-order function feature would be
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="#all"
version="3.0">
<xsl:template match="/">
<xsl:value-of
select="distinct-values(
BookCollection/Book[status = 'In Stock'] ! sort(OrderHistory/Order, (), function($order) { xs:date($order/date) })[last()]/Delivery
)"
separator=", "/>
</xsl:template>
</xsl:stylesheet>
In XSLT 3 processors like Saxon 9.8 HE where the higher-order variant of sort is not supported you need to delegate the sorting to your own function:
<xsl:template match="/">
<xsl:value-of
select="distinct-values(
BookCollection/Book[status = 'In Stock'] ! mf:sort(OrderHistory/Order)[last()]/Delivery
)"
separator=", "/>
</xsl:template>
<xsl:function name="mf:sort" as="element(Order)*">
<xsl:param name="orders" as="element(Order)*"/>
<xsl:perform-sort select="$orders">
<xsl:sort select="xs:date(date)"/>
</xsl:perform-sort>
</xsl:function>
Example at https://xsltfiddle.liberty-development.net/bdxtqs.