XSLT generate table out of child nodes in same parent node - xslt

Question

I need to generate a table out of one parent node.
The XML snipped looks like this:
<persons>
<name>John</name>
<age>30</age>
<city>London</city>
<name>Jake</name>
<age>28</age>
<city>New York</city>
</persons>
But sometimes it can look like that:
<persons>
<name>John</name>
<age>30</age>
<name>Jake</name>
<age>28</age>
</persons>
The generated table should look the same for both cases, so like these:
<table>
<tbody>
<tr>
<th>Name</th>
<th>Age</th>
<th>City</th>
</tr>
<tr>
<td>John</td>
<td>30</td>
<td>London</td>
</tr>
<tr>
<td>Jake</td>
<td>28</td>
<td>New York</td>
</tr>
</tbody>
</table>
Or in the other case:
<table>
<tbody>
<tr>
<th>Name</th>
<th>Age</th>
<th>City</th>
</tr>
<tr>
<td>John</td>
<td>30</td>
<td></td>
</tr>
<tr>
<td>Jake</td>
<td>28</td>
<td></td>
</tr>
</tbody>
</table>
I know what tags can be in <persons>.
But I don't know how to do this in xslt.

Answer 1

As you are using XSLT 2.0, you can use the xsl:for-each-group construct for this, so you are grouping elements starting with the name element
Try this XSLT. This assumes name will always be present, and be the first element in the group. age and city need not be present though.
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output method="html" indent="yes" html-version="5"/>
<xsl:template match="persons">
<table>
<tr>
<th>Name</th>
<th>Age</th>
<th>City</th>
</tr>
<xsl:for-each-group select="*" group-starting-with="name">
<tr>
<td><xsl:value-of select="." /></td>
<td><xsl:value-of select="current-group()[self::age]" /></td>
<td><xsl:value-of select="current-group()[self::city]" /></td>
</tr>
</xsl:for-each-group>
</table>
</xsl:template>
</xsl:stylesheet>