Calling a Myrange Function in a Sub - regex

Question

I put together a regex function that will remove all whitespace from a column, and when I use it on a sheet I just have to type in =simplecellregex() then I run that in the new column against all of the entries. The reason I am doing it this way is because TRIM() does not work always so I looked for a way that did.
Function simpleCellRegex(Myrange As Range) As String
Dim Regex As New RegExp
Dim strPattern As String
Dim strInput As String
Dim strReplace As String
Dim strOutput As String
strPattern = "\s+$"
If strPattern <> "" Then
strInput = Myrange.Value
strReplace = ""
With Regex
.Global = True
.MultiLine = True
.IgnoreCase = False
.Pattern = strPattern
End With
If Regex.Test(strInput) Then
simpleCellRegex = Regex.Replace(strInput, strReplace)
Else
simpleCellRegex = strInput
End If
End If
End Function
Sub regex1()
Column.Add
Range("D2").Value = simpleCellRegex(Myrange, String)
End Sub
So this was the setup so that whenever I get workbooks I just click the column I want the function to run on and it runs the regex and spits it out the the column next to it. The plan is to make this a macro so I can just add a button on the excel menu ribbon and make this regex easy to run.

Answer 1

EDIT:
Use the following if you want to select a range and then press a button
Option Explicit
Public Sub RemoveEndWhiteSpace()
Dim arr(), i As Long, myRange As Range
Set myRange = Selection
If myRange.Columns.Count > 1 Or myRange Is Nothing Then Exit Sub
If myRange.Count = 1 Then
myRange = RTrim$(myRange.Value)
Exit Sub
Else
arr = myRange.Value
For i = LBound(arr, 1) To UBound(arr, 1)
arr(i, 1) = RTrim$(arr(i, 1))
Next i
myRange = arr
End If
End Sub
To output to a different column:
myRange.Offset(, 1) = arr '<==use offset to put result in a different column e.g. one to the right
Example run of the last bit of code tied to a button (where macro is set to all open workbooks btw)
tl;dr;
If you want to click on a column and trailing white space be removed something like the following. This uses a worksheet event of when you select a column to run the sub. The sub checks how many cells are populated in the column and works with those.
Private Sub Worksheet_SelectionChange would go in the code pane for the sheet you are wanting to do the replacement on.
.UsedRange is not always the most reliable method.
The sub it calls would go in a standard module. I suspect there are more efficient ways to do this to be honest but thought I would have a quick play.
Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Cells.Count = Columns(1).Cells.Count And Target.Columns.Count = 1 Then
'MsgBox "running"
RemoveEndWhiteSpace Intersect(Target, Me.UsedRange)
End If
End Sub
Public Sub RemoveEndWhiteSpace(ByVal myRange As Range)
Dim arr(), i As Long
If myRange.Count = 1 Then
myRange = RTrim$(myRange.Value)
Exit Sub
Else
arr = myRange.Value
For i = LBound(arr, 1) To UBound(arr, 1)
arr(i, 1) = RTrim$(arr(i, 1))
Next i
myRange = arr
End If
End Sub
More reliable for used range of column would be:
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Cells.Count = Columns(1).Cells.Count And Target.Columns.Count = 1 Then
' MsgBox "running"
Dim lastRow As Long, myRange As Range
lastRow = Cells(Rows.Count, Target.Column).End(xlUp).Row
Set myRange = Range(Cells(1, Target.Column), Cells(lastRow, Target.Column))
RemoveEndWhiteSpace myRange
End If
End Sub