Can't initialize D struct member with Range - d

Question

I'm attempting to learn D and ran into an issue with structs and initialization. When the following code is compiled as rdmd -version=templat code.d, I get a bunch of errors like:
> dmd -version=templat code.d
D:\D\dmd2\windows\bin\..\..\src\phobos\std\random.d(1610): Error: static variable initialized cannot be read at compile time
D:\D\dmd2\windows\bin\..\..\src\phobos\std\random.d(1653): called from here: rndGen()
D:\D\dmd2\windows\bin\..\..\src\phobos\std\random.d(1653): called from here: uniform(a, b, rndGen())
code.d(8): called from here: uniform(1u, 7u)
D:\D\dmd2\windows\bin\..\..\src\phobos\std\range\package.d(3470): called from here: (*function () => uniform(1u, 7u))()
D:\D\dmd2\windows\bin\..\..\src\phobos\std\range\package.d(3387): called from here: gen.popFront()
code.d(8): called from here: generate()
code.d(13): Error: template instance `code.Dice!(1u, 7u)` error instantiating
I assume this has something to do with needing to be able to statically resolve the uniform(Lo, Hi). But I am at a loss as to how solve this issue. When I compile with rdmd -version=variabl code.d, I encounter no issues.
For what it's worth, my goal is to be able to define a "dice" type so that I can implement ranges, operator overloading, etc. on it to get a feel for this in D.
import std.range : generate ;
import std.random : uniform ;
version(templat)
{
struct Dice(uint Lo, uint Hi)
{
auto values = generate!(() => uniform(Lo, Hi));
}
void main()
{
Dice!(1, 7) d6;
}
}
version(variabl)
{
void main()
{
auto d6a = generate!(() => uniform(1, 7));
}
}

Answer 1

In order for generate! to work it needs to cache the first result when it's constructed, but setting a default struct values happens at compile-time. (so tries to run uniform() using ctfe...)
What you could do is use alias like this:
import std.range : take, generate;
import std.random : uniform;
import std.stdio, writeln;
alias Dice(uint Lo, uint Hi) = generate!(() => uniform(Lo, Hi));
void main()
{
auto d6 = Dice!(1, 7);
writeln(d6.front);
writeln(d6.front); // same as above because you didnt pop it
d6.popFront();
writeln(d6.front);
d6.popFront();
d6.take(3).writeln;
}
Also, here is an example of createing a range directly without useing generate!.
import std.range : take;
import std.random : uniform;
import std.stdio, writeln;
struct Dice(uint Lo, uint Hi)
{
void popFront()
{
front = uniform(Lo, Hi);
}
static bool empty = false;
uint front;
}
auto makeDice(uint Lo, uint Hi)(){
auto dice = Dice!(Lo, Hi)();
dice.popFront();
return dice;
}
void main()
{
auto d6 = makeDice!(1, 7);
writeln(d6.front);
writeln(d6.front); // same as above because you didnt pop it
d6.popFront();
writeln(d6.front);
d6.popFront();
d6.take(3).writeln;
}