sas count changes between date and variable grouped by id - sas

Question

I'm trying to get the count of changes in default variable based on ID and Date. I'm a week old into using SAS so please forgive me if I need detailed explanations.
I currently have
data test111;
input Date $ Acc $ Default $;
datalines;
jan-10 A N
feb-10 A D
mar-10 A D
apr-10 A D
may-10 A D
jan-10 B N
feb-10 B N
mar-10 B D
apr-10 B D
may-10 B D
jan-10 C N
feb-10 C N
mar-10 C N
apr-10 C D
may-10 C D
jan-10 D N
feb-10 D D
mar-10 D N
apr-10 D D
may-10 D D
jan-10 E D
feb-10 E D
mar-10 E D
apr-10 E N
may-10 E D
I want an output (Table 1 below) that counts when default changes from N to D for each unique accounts. But it is dependent on Date. I only know how to use Excel to show the output desired (manually counting). Table 2 is how the accounts are counted if I'm not clear.
Table 1
month+1 month+2 month+3 month+4
Jan-10 2 1 1 0
Feb-10 1 1 0
Mar-10 2 0
Apr-10 1
Table 2 (FYR)
month+1 month+2 month+3 month+4
Jan-10 A,D B C -
Feb-10 B C -
Mar-10 C,D -
Apr-10 E
I've tried something like creating a new column that tags when N changes to D so I can sum when tag =1
by first.Acc
if first.Acc then tag = 0;
if default = 'D' then do;
tag = 1;
tag+1;
Not sure if this will get me the correct result for my first line.
But if this works it can only give me the first row of my desired output. I have over 100 months and is it possible to loop or array it?
In case my SAS data input skills fail I've included the Excel screenshot.
Excel screenshot

Answer 1

The most general solution will involve a full outer join within each group.
SQL can perform the join and compute the months apart for the case of a month with N default to the next earliest month with D default. Tabulate can present a grid of the counts.
Data
The month strings are converted to SAS 1-st of month date values that are formatted yymon for display purposes.
data have;
input Date $ Acc $ Default $;
month = input ('01-'||date, date9.);
format month yymon.;
datalines;
jan-10 A N
feb-10 A D
mar-10 A D
apr-10 A D
may-10 A D
jan-10 B N
feb-10 B N
mar-10 B D
apr-10 B D
may-10 B D
jan-10 C N
feb-10 C N
mar-10 C N
apr-10 C D
may-10 C D
jan-10 D N
feb-10 D D
mar-10 D N
apr-10 D D
may-10 D D
jan-10 E D
feb-10 E D
mar-10 E D
apr-10 E N
may-10 E D
run;
Sample SQL
proc sql;
create view have_v as
select
left.acc
, left.month as from_month
, right.month as to_month
, intck ('MONTH', left.month, right.month) as months_apart
from
have as left
join have as right on left.acc = right.acc
where
left.month < right.month
& left.default = 'N'
& right.default = 'D'
group by left.acc, left.month
having right.month = min(right.month)
order by
left.month, right.month
;
create table grid_bounds as
select
min(from_month) as min_from
, max(from_month) as max_from
, 1 as min_apart
, max(months_apart) as max_apart
from have_v
;
SQL Explained
A self join is a join of a table against itself.
have as left join have as right
The join constraint restricts the from/to month combinations to be only those in the same account
on left.acc = right.acc
The where constraint further restricts the from/to combinations to be only those with to in the future and having the desired default transition
where
left.month < right.month
& left.default = 'N'
& right.default = 'D'
The group by operator and SAS Proc SQL having clause automatic remerge feature allows a simple statement for selecting the earliest to for a given from
group by left.acc, left.month
having right.month = min(right.month)
For the selected rows of the join the months apart can be computed using SAS data function INTCK (I think of the function name as an acronym for the phrase "INTerval Count of a period Kind")
, intck ('MONTH', left.month, right.month) as months_apart
A specific solution could use array if the largest group size is known apriori.
Tabulate for output
Some months may not be present due to no transitions. Likewise, some gaps may also not be present. These cases will not have any rows in have_v. In order to get a full coverage for the report, all possible crossings (or combinations) are generated for use in Proc TABULATE
proc sql;
create table grid_bounds as
select
min(from_month) as min_from
, max(from_month) as max_from
, 1 as min_apart
, max(months_apart) as max_apart
from have_v
;
quit;
data grid (label="All crossings to be shown in the output");
set grid_bounds;
do from_month = min_from to max_from;
do months_apart = 1 to max(12,max_apart);
OUTPUT;
end;
end;
keep from_month months_apart;
format from_month yymon.;
run;
Outputs a grid report with gap frequencies for each from_month
options missing = '0' nocenter;
title "Account frequency";
title2 "Gap of month default changing from N to D";
proc tabulate data=have_v classdata=grid;
class from_month months_apart;
table
from_month=''
, months_apart * N=''
;
run;
options missing = '.';