Memory leaking with using same pointer to numerous target - fortran

Question

My IDE is Visual Studio 2010 with integrated Intel Fortran compiler. The version of compiler is: Intel Parallel Studio XE 2011.
I am not experienced programer in Fortran so I need a little help about using pointers in reading data from .txt files. This is my example code:
Module Derived_type
implicit none
Type , public :: Something
private
Real :: Somth_1
Integer :: Somth_2
contains
procedure , public :: read_input => read_data_input
procedure , public :: t_Somth_1 => t_data_Somth_1
procedure , public :: t_Somth_2 => t_data_Somth_2
End Type Something
private :: read_data_input
private :: t_data_Somth_1 , t_data_Somth_2
contains
Subroutine read_data_input( This , Un_r )
Class( Something ) :: This
Integer , intent( in ) :: Un_r
Read ( Un_r , * , Err = 100 ) This%Somth_1
Read ( Un_r , * , Err = 101 ) This%Somth_2
Return
100 Stop ( "Read format error - 100 !!!" )
101 Stop ( "Read format error - 101 !!!" )
End Subroutine read_data_input
Function t_data_Somth_1 ( This ) result( data_Somth_1 )
Class( Something ) :: This
Real :: data_Somth_1
data_Somth_1 = This%Somth_1
End Function t_data_Somth_1
Function t_data_Somth_2 ( This ) result( data_Somth_2 )
Class( Something ) :: This
Integer :: data_Somth_2
data_Somth_2 = This%Somth_2
End Function t_data_Somth_2
End Module Derived_type
Program Memory_leaking
Use , non_intrinsic :: Derived_type
Implicit none
Integer :: i , alloc_err , dealloc_err
Integer , parameter :: N_snv = 3
Character( 256 ) :: Name
Character(*),parameter :: a00 = '("Input_",i1,".txt")'
Class( Something ) , pointer :: Po_Something
Type( Something ) , allocatable , target :: Tar_Something(:)
! Memory allocation
allocate ( Po_Something , Stat = alloc_err )
If ( alloc_err .ne. 0 ) Stop ( "Allocation wrong - Po_Something !!!")
If ( .not. allocated ( Tar_Something ) ) allocate( Tar_Something( N_snv ) , stat = alloc_err )
If ( alloc_err .ne. 0 ) Stop ( "Allocation wrong - Tar_Something !!!")
Do i = 1 , N_snv
Po_Something => Tar_Something(i)
Write( Name , a00 ) i
Open( 15 , File = Name , Status = 'Unknown' , Action = 'Read' )
Call Po_Something%read_input( 15 )
Close( 15 , Status = 'Keep' )
Write(*,*) Po_Something%t_Somth_1() , Po_Something%t_Somth_2()
End Do
! Memory deallocation
deallocate ( Po_Something , Stat = dealloc_err )
If ( dealloc_err .ne. 0 ) Stop ( "deAllocation wrong - Po_Something !!!")
If ( allocated ( Tar_Something ) ) deallocate( Tar_Something, stat = dealloc_err )
If ( dealloc_err .ne. 0 ) Stop ( "deAllocation wrong - Tar_Something !!!")
End program Memory_leaking
I have a one array which is derived type and I want to read data from .txt file for every single array using same pointer, just like in my example code.
I there need for breaking conection beatwean pointer and target in afther do loop execution was done?
Is there memory leaking in this case?

Answer 1

Yes, you have a memory leak.
allocate ( Po_Something , Stat = alloc_err )
Here you allocated, manually, storage for your pointer variable and pointed to its memory address.
Po_Something => Tar_Something(i)
Just after, you changed the poitee to another storage (the allocatable variable) and left behind the storage you allocated before. After this pointer association, there is no reference left anymore pointing to the address you allocated manually. The program won't be able to deallocate it when it reaches the end.
As you are not using the storage of the first allocation, the solution here is just not doing it. The pointer will point to memory already allocated in the loop.
Allocatable variables are deallocated automatically (in modern Fortran), but any memory you allocated manually for a pointer variable need to be manually deallocated before you change the its target.
Check my other answer about when manual deallocation is needed for reference.
When is array deallocating necessary?
(better than that, download a copy of the Fortran Standard for reference here https://wg5-fortran.org )