Concatenate column names with non zero values - sas

Question

There is a table that have ID, event, date.
The current script counts events by id, event_type and date, transposes and then labels each ID by the combination of events types that day.
The concern is this breaks if new event types appear.
I am hoping to find a method that takes all the column names with non zero count and concatenates them. Ideally this method does not involve hard coding the events.
data test;
infile datalines delimiter=':' truncover;
informat id 10. event_dt DDMMYY10. event_type $10. event $10.;
input id event_dt event_type event;
datalines;
1:01-03-2017:BB:b1
1:01-03-2017:AA:A2
1:02-03-2017:CC:C1
2:01-03-2017:CC:C2
3:03-03-2017:BB:b2
4:02-03-2017:AA:A1
;
run;
proc sql;
create table test2 as
select distinct ID, event_dt format worddate. as event_dt, event_type, count(distinct event) as event_count
from test
group by ID, event_dt, event_type;
quit;
proc transpose data=test2 out=test3 (drop = _name_);
by id event_dt;
id event_type;
run;
proc stdize data=test3 out=test3z reponly missing=0;
run;
proc sql;
create table test4 as
select event_dt,
case when AA = 0 and BB = 0 and CC = 0 then 'No Event'
when AA = 0 and BB = 0 and CC > 0 then 'CC only'
when AA = 0 and BB > 0 and CC = 0 then 'BB only'
when AA = 0 and BB > 0 and CC > 0 then 'BB & CC'
when AA > 0 and BB = 0 and CC = 0 then 'AA only'
when AA > 0 and BB = 0 and CC > 0 then 'AA & CC'
when AA > 0 and BB > 0 and CC = 0 then 'AA & BB'
when AA > 0 and BB > 0 and CC > 0 then 'AA & BB & CC'
else 'Other' end as tag, count(id) as ID_COUNT
from test3z group by
event_dt,
case when AA = 0 and BB = 0 and CC = 0 then 'No Event'
when AA = 0 and BB = 0 and CC > 0 then 'CC only'
when AA = 0 and BB > 0 and CC = 0 then 'BB only'
when AA = 0 and BB > 0 and CC > 0 then 'BB & CC'
when AA > 0 and BB = 0 and CC = 0 then 'AA only'
when AA > 0 and BB = 0 and CC > 0 then 'AA & CC'
when AA > 0 and BB > 0 and CC = 0 then 'AA & BB'
when AA > 0 and BB > 0 and CC > 0 then 'AA & BB & CC'
else 'Other' end;
quit;
Thank you
Ben

Answer 1

Some might say, transpose and use arrays.
Consider this alternative -- instead of assigning the tag value by processing explicit columns across a row.
Compute the tag value while iterating through the id/date group, sorting and then counting the ids while iterating through the date/tag group.
* same as in question;
proc sql;
create table test2 as
select distinct ID, event_dt format worddate. as event_dt, event_type, count(distinct event) as event_count
from test
group by ID, event_dt, event_type;
quit;
* compute tag value (I call it type_list);
data test2a;
length type_list $30;
do _n_ = 1 by 1 until (last.event_dt);
set test2;
by ID event_dt;
type_list = catx(',',type_list,event_type);
end;
keep id event_dt type_list;
run;
proc sort data=test2a;
by event_dt type_list;
run;
* count number of ids with same type list on each event day;
data want;
do id_count = 1 by 1 until (last.type_list);
set test2a;
by event_dt type_list;
end;
run;
You can add extra logic and tranwrd to change the type_list (a csv list) to a more verbose representation (contain words and or & or only)