How to read a file creating a list - list

Question

I have some code, looks like this:
main :-
open('input.txt', read, Input),
repeat,
read_line_to_codes(Input, Line),
maplist(my_representation, Line, FinalLine),
( Line \= end_of_file -> writeln(FinalLine), fail ; true ),
close(Input).
FinalLine is a list of integers, including some underscores (based on the input file). Since this loops, I am wondering how to dynamically, each iteration of the loop, add the FinalLine list to another list. Basically this will create a list of lists.
And since I know the specifications of my input file, I know it loops 16 times, therefore I want a list of 16 lists. So although I don't know how to do this, I am pretty sure the best way would be to make a predicate that I call, instead of the output I am doing now (writeln(FinalLine)), to dynamically create this list of lists.
Hope this makes sense. Would appreciate any help, thanks!

Answer 1

While historically I/O in Prolog was often presented in terms of repeat/fail loops, recursion is often (almost always?) the superior way to implement iteration. Especially if you need to remember data from one iteration to the next; failing causes backtracking, which unbinds your variables from the previously computed data. On backtracking you lose any data you had not saved away using yet more impure constructs. Recursion is simpler.
Recursion forces you to decompose the program into more than one predicate, but that is a good idea anyway. For example, separating opening the stream from reading it makes your program more reusable and more testable, because streams may be constructed from things other than files.
% dummy
my_representation(Codes, Result) :-
atom_codes(Result, Codes).
stream_representations(Input, Lines) :-
read_line_to_codes(Input, Line),
( Line == end_of_file
-> Lines = []
; my_representation(Line, FinalLine),
Lines = [FinalLine | FurtherLines],
stream_representations(Input, FurtherLines) ).
main :-
open('input.txt', read, Input),
stream_representations(Input, Lines),
close(Input),
writeln(Lines).
Test input file:
hello
world
hello, world!
this file ends here
Test run:
?- main.
[hello,world,hello, world!,this file ends here]
true.

Answer 2

A 2-dimensional list of lists is a matrix, and the easiest way to visualize it in your head is a table consisting of rows and columns. Here's a piece of example code to clarify the concept.
This code generates a matrix based on the maximum amounts of columns you want as MaxX, and the maximum amount of rows you want as MaxY. Each position in the matrix has a cell(point(X,Y)) coordinate to visualize the output more easily.
%If the MaxY has been reached for the Y axis, step back
generate_matrix([],_,_,MaxY,MaxY) :- !.
%If MaxX has been reached, new row
generate_matrix([Row|Tp],X,MaxX,Y,MaxY):-
generate_row(Row, X, MaxX, Y),
Y1 is Y+1,
generate_matrix(Tp,0,MaxX,Y1,MaxY).
%If the MaxX has been reached for the X axis, step back
generate_row([], MaxX,MaxX,_) :- !.
generate_row([cell(point(X,Y))|T], X, MaxX, Y) :-
XNew is X + 1,
generate_row(T, XNew, MaxX, Y).
You could easily replace cell(point(X,Y) with something you want to place there instead. I hope this clarifies the concept for you, be sure to ask for clarification if it doesn't.
Testquery to generate a 10 by 10 matrix/grid/table/2-dimensional list of lists:
%generate_matrix(Matrix, 0, MaxX, 0, MaxY)
generate_matrix(Matrix, 0, 10, 0, 10).
You can add dimensions to represent more complex structures. Adding a Z-axis gives you a 3D-cube.