Split comma separated string into multiple values using xslt - xslt

Question

I need to split two tags with comma separated string into a list of parent-child tags as shown below.
For example, the input will be :-
<UserID>162,163</UserID>
<UserName>Stacy,Stephen</UserName>
Expected output :-
Expected Output
Please help to achieve this result using xslt code
I tried the following format which I got from another query, but its generating a nested pattern instead of the list :-
<xsl:template name="tokenize">
<xsl:param name="textID" select="."/>
<xsl:param name="textName" select="."/>
<xsl:param name="separator" select="','"/>
<User>
<xsl:choose>
<xsl:when test="not(contains($textID, $separator))">
<ID>
<xsl:value-of select="normalize-space($textID)"/>
</ID>
</xsl:when>
<xsl:otherwise>
<ID>
<xsl:value-of select="normalize-space(substring-before($textID, $separator))"/>
</ID>
<xsl:call-template name="tokenize">
<xsl:with-param name="textID" select="substring-after($textID, $separator)"/>
<xsl:with-param name="textName" select="substring-after($textName, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
<xsl:choose>
<xsl:when test="not(contains($textName, $separator))">
<Name>
<xsl:value-of select="normalize-space($textName)"/>
</Name>
</xsl:when>
<xsl:otherwise>
<Name>
<xsl:value-of select="normalize-space(substring-before($textName, $separator))"/>
</Name>
<xsl:call-template name="tokenize">
<xsl:with-param name="textID" select="substring-after($textID, $separator)"/>
<xsl:with-param name="textName" select="substring-after($textName, $separator)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</User>
</xsl:template>

Answer 1

There are few assumptions before simplifying the tokenize template shared in the XSLT code.
The count of comma separated values in <UserID> and <UserName> is always equal.
There is a 1-1 correspondence on the indexes of the values i.e. 162 <-> Stacy and 163 <-> Stephen.
XSLT version is 1.0
A parent node <UserList> has been added as a root node for the shared input XML.
XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:template match="UserList">
<xsl:copy>
<xsl:call-template name="tokenize">
<xsl:with-param name="textID" select="normalize-space(UserID)" />
<xsl:with-param name="textName" select="normalize-space(UserName)" />
</xsl:call-template>
</xsl:copy>
</xsl:template>
<xsl:template name="tokenize">
<xsl:param name="textID" />
<xsl:param name="textName" />
<xsl:param name="separator" select="','" />
<xsl:choose>
<xsl:when test="not(contains($textID, $separator) and contains($textName, $separator)) ">
<User>
<ID><xsl:value-of select="$textID" /></ID>
<Name><xsl:value-of select="$textName" /></Name>
</User>
</xsl:when>
<xsl:otherwise>
<User>
<ID><xsl:value-of select="substring-before($textID, $separator)" /></ID>
<Name><xsl:value-of select="substring-before($textName, $separator)" /></Name>
</User>
<xsl:call-template name="tokenize">
<xsl:with-param name="textID" select="normalize-space(substring-after($textID, $separator))" />
<xsl:with-param name="textName" select="normalize-space(substring-after($textName, $separator))" />
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
Output
<UserList>
<User>
<ID>162</ID>
<Name>Stacy</Name>
</User>
<User>
<ID>163</ID>
<Name>Stephen</Name>
</User>
</UserList>