How to extract the second pattern from a line of text? - regex

Question

Let me preface my question with the fact that I am doing this on an AS/400, and IBM really sucks at keeping their utilities up to date. I want to extract a pattern like /[a-zA-Z0-9]*.LIB/ but the second match that is found. Look at how the two paths below differ:
/QSYS.LIB/KDBDFC1_5.LIB/AUTNOTMAIN.PGM
/DATADEV/QSYS.LIB/FPSENGDEV.LIB/AUTNOTMAIN.PGM
So, in this case I want KDBDFC1_5.LIB and FPSENGDEV.LIB, not QSYS.LIB.
I've tried to use gawk with the match() function and store my matches in an array, but it seems I cannot have a third parameter with match() "match() cannot have 3 arguments". Our version of gawk is 3.0.3. Yeah. I'm fooling around with perl, trying to make this work in a command line setting. Our version of perl is 5.8.7. Should your answer include some fancy new option in grep, you may also consider the QSH version of grep equally old, although there are the PASE utilities, if you know what those are.
I'm still banging on this one, but would appreciate any suggestions as I'm likely to develop a headache soon. :-)

Answer 1

You probably need last-1 segment. Following awk should work:
awk -F/ '{print $(NF-1)}' file
KDBDFC1_5.LIB
FPSENGDEV.LIB
Or probably this awk would work by searching for .LIB and print 2nd field:
awk -F'.LIB' '{print substr($2,2) FS}' file
KDBDFC1_5.LIB
FPSENGDEV.LIB

Answer 2

How about
perl -lne '#matches = /(\w+\.LIB)/g; print $matches[1] if #matches > 1' file

Answer 3

If match does not support array output, you could run matching twice, discarding the first match, and printing the second:
$ awk '{p="[a-zA-Z0-9_]*.LIB"; sub(p,""); match($0,p); print substr($0,RSTART,RLENGTH)}' file
KDBDFC1_5.LIB
FPSENGDEV.LIB

Answer 4

return the second occurence of <word>.LIB :
perl -pe 's/^(?:.*?\.LIB).*?([\w_.]*.LIB).*$/\1/g'
return the last occurence of <word>.LIB :
perl -pe 's/^(?:.*\.LIB).*?([\w_.]*.LIB).*$/\1/g' file
^ start with
(?:.*\.LIB) uncapturing group containing .LIB
.*? anythings ungreedy
([\w.]*.LIB) first capturing group <word>.LIB
.* anythings greedy
$ finish by

Answer 5

So ... after adding an underscore to the search regex, the following worked for me:
sed 's/.*\/\([[:alnum:]_]*\.LIB\).*/\1/' file
Of course, you could also do this with grep -o instead of complex regex rewrites:
grep -o '[[:alnum:]_]*\.LIB' file | awk 'NR%2==0'
These use only POSIX-compatible functionality, so they should be fine in OS/400. That said, you're looking for this in awk, so:
awk '{sub(/.*QSYS\.LIB\//,""); sub(/\/.*/,"")}1' file
If you know that QSYS.LIB is the thing you're trying to avoid which may exist earlier on the line, then this might do. And if it really is the second of two .LIB files you want, this might do:
awk '{match($0,/[[:alnum:]_]+\.LIB/); s=substr($0,RSTART+RLENGTH); match(s,/[[:alnum:]_]+\.LIB/); print substr(s,RSTART,RLENGTH)}' file
Or, broken out for easier reading:
awk '{
match($0,/[[:alnum:]_]+\.LIB/);
s=substr($0,RSTART+RLENGTH);
match(s,/[[:alnum:]_]+\.LIB/);
print substr(s,RSTART,RLENGTH)
}' file
This uses only plain-old-awk functions match() and substr() to (1) strip off the first .LIB from and store the remainder of the line in a temporary variable, and (2) find the next .LIB inside that variable.
It has the advantage of not depending on any particular position of things -- i.e. it doesn't assume that the "interesting" file is immediately after the first one, or is the second last one on the line, etc.
That said, this is cumbersome, and anubhava's second solution is much more elegant. :-)