Replace variable length string with characters to matching original string length - regex

Question

I am using a regular expression:
>\.*<
to match certain parts of field3 but I can't figure out how to replace with a number of characters that would preserve the original string length.
Input:
field1 field2 >>>>>.>............>>>.........<<<.......>>>>.......<<<<.<.<<<<<.
Expected output:
field1 field2 >>>>>.>............>>LLLLLLLLLLL<<.......>>>LLLLLLLLL<<<.<.<<<<<.
My poor failing attempt:
awk 'match($3, />\.*</){split($3, sst, "");for(i=RSTART;i<=RLENGTH;i++){sst[i]="L"};joined=sep="";for(x=1; x in sst;x++){joined=joined sep sst[x];sep=""};printf("%s\n", joined)}' hg19-matRNA.tsv > test2.tsv
Any help would be greatly appreciated!

Answer 1

With GNU awk for the 3rd arg to match() and gensub():
$ cat tst.awk
{
while ( match($3,/(.*)(>\.*<)(.*)/,a) ) {
$3 = a[1] gensub(/./,"L","g",a[2]) a[3]
}
print
}
$ awk -f tst.awk file
field1 field2 >>>>>.>............>>LLLLLLLLLLL<<.......>>>LLLLLLLLL<<<.<.<<<<<.
With any awk:
$ cat tst.awk
{
while ( match($3,/>\.*</) ) {
tgt = substr($3,RSTART,RLENGTH)
gsub(/./,"L",tgt)
$3 = substr($3,1,RSTART-1) tgt substr($3,RSTART+RLENGTH)
}
print
}
$ awk -f tst.awk file
field1 field2 >>>>>.>............>>LLLLLLLLLLL<<.......>>>LLLLLLLLL<<<.<.<<<<<.

Answer 2

awk solution. You could use patsplit as well like this:
$ cat tst.awk
{
patsplit($3, a, ">\\.+<", seps)
l=(length(a)>length(seps)?length(a):length(seps))
for (i=0; i<l; i++){
if (i in a) gsub(/./,"L",a[i])
s=s sprintf("%s", (i in a)?a[i]seps[i]:seps[i])
}
$3=s
}1
$ awk -f tst.awk file
field1 field2 >>>>>.>............>>LLLLLLLLLLL<<.......>>>LLLLLLLLL<<<.<.<<<<<.