Relative Positioning Text Extraction Failing - imacros

Question

I'm trying to extract player values from hockey-resource from player pages, and I've hit a snag around pulling out the position and handedness of players as well as height and weight.
I can pull out the whole row but then it's formatted poorly and doesn't work for what I'll eventually do (loop through the player pages and save into the table next to the original name). Here's what I've got so far:
VERSION BUILD=9030808 RECORDER=FX
TAB T=1
URL GOTO=https://www.hockey-reference.com/players/d/duchema01.html
TAG POS=R1 TYPE=STRONG ATTR=TXT:Shoots EXTRACT=TXT
SAVEAS TYPE=EXTRACT FOLDER=* FILE=nhlplayerrecord_duchema01.csv
this totally fails, although given the documentation it seems like that should be prime territory to work. Here's the bits that pull full row:
VERSION BUILD=9030808 RECORDER=FX
TAB T=1
URL GOTO=https://www.hockey-reference.com/players/d/duchema01.html
TAG POS=1 TYPE=P ATTR=TXT:* EXTRACT=TXT
TAG POS=2 TYPE=P ATTR=TXT:* EXTRACT=TXT
SAVEAS TYPE=EXTRACT FOLDER=* FILE=nhlplayerrecord_duchema01.csv
Any advice on what I've missed or how I might better position this to find the values would be great.
using Firefox, mac OSX
thanks

Answer 1

In your first snippet you use relative positioning in your TAG POS=R1. Relative positioning requires a previous TAG command to find the next position, though, which you do not have. That's why your first snippet fails at that line.
<p>
<strong>Position</strong>: C •
<strong>Shoots</strong>: Left
</p>
If you only want the 'C' and the 'Left' in this specific example you could extract the entire P as you do in your second snippet and drop all the unneeded parts with an EVAL statement.
The following reads C and Left and writes them to the specified file, you can proceed similarly for height and weight.
VERSION BUILD=9030808 RECORDER=FX
TAB T=1
URL GOTO=https://www.hockey-reference.com/players/d/duchema01.html
TAG POS=1 TYPE=P ATTR=TXT:* EXTRACT=TXT
' Create an extract backup, it's overwritten to save data
SET extract_backup {{!EXTRACT}}
' Read and save Position
SET !EXTRACT EVAL("var pos='{{extract_backup}}'.split('•'); pos[0].split(':')[1].replace(/ /g,'');")
SAVEAS TYPE=EXTRACT FOLDER=* FILE=nhlplayerrecord_duchema01.csv
' Read and save Shoots
SET !EXTRACT EVAL("var shoots='{{extract_backup}}'.split('•'); shoots[2].split(':')[1].replace(/ /g,'');")
SAVEAS TYPE=EXTRACT FOLDER=* FILE=nhlplayerrecord_duchema01.csv