Extract specific values from a log file - regex

Question

I want to extract two values on the same line of a log file using Perl.
Network Next Hop metric locprf Path
*|i10.1.5.0/24 10.6.76.242 2 100 0 65000?
*|i10.1.9.0/24 10.6.76.242 2 100 0 64345 63800?
*|i10.2.9.0/25 10.6.76.242 2 100 0?
For each line, I want to extract the network address and the number before the ?
I have this but it extracts only the network address.
open( CONF, '<', 'putty-wan.log' ) or die "\n";
my #ip;
open( FICHE, ">RouterNetwork.txt" ) || die ( "Vous ne pouvez pas créer le fichier \"RouterNetwork.txt\"" );
while ( my $line = <CONF> ) {
if ( $line =~ /(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}\/\d{1,2})/ ) {
print FICHE $1, "\n";
}
}
close(FICHE);
close CONF;
Now I want the regular expression to add or any way to get per line, the network address and the number just before ?.

Answer 1

Given the shown format, you can process the line with
my ($ip, $n) = map { s/^\D*|\D*$//gr } (split ' ', $line)[0,-1];
or, when the line is in the $_ variable
my ($ip, $n) = map { s/^\D*|\D*$//gr } (split)[0,-1];
With the /r non-desctructive modifier the new string is returned (leaving the original unchanged, what we don't care about here). It's available since v5.16. If your version of Perl is older use
my ($ip, $n) = map { s/^\D*|\D*$//g; $_ } (split)[0,-1];
As for processing the whole file, you need a way to detect header lines. How to do this depends on details of your file format. Given the sample, perhaps skip lines starting with letter-only words
use warnings;
use strict;
use feature 'say';
my $file = 'putty-wan.log';
open my $fh, '<', $file or die "Can't open $file: $!";
while (<$fh>)
{
next if /^[a-zA-Z]+\b/;
my ($ip, $num) = map { s/^\D*|\D*$//gr } (split)[0,-1];
say "$ip $num";
}
Some comments
Please always start with use warnings;, and with use strict;
Use three-argument form of open, with a lexical filehandle. It's better
Always include $! in your die statements, to see the actual error. This would be the "default" way to do it while sometimes other error variables are needed as well.
While there is nothing wrong with using || as you do, the or is very handy for flow control, having a suitably lower precedence. But above all, it's good to be consistent in any case.
It's been clarified that the last part on the line can also be 6500 ? or 65000 i or such.
Then store all fields in an array and process it from the back, looking for the first field with numbers.
while (<$fh>)
{
next if /^[a-zA-Z]+\b/;
my #fields = split;
my $ip = (shift #fields) =~ s/^\D*//gr; #/# need v5.16 for /r
my $num;
while (my $f = pop #fields) {
($num) = $f =~ /(\d+)/;
last if $num;
}
say "$ip $num";
}
The IP is still obtained from the first field, and cleaned up the same way as before.

Answer 2

There are nothing particular to do, only to continue the line description with the number you want to capture:
use strict;
use warnings;
open (my $conf, '<', 'putty-wan.log') || die "Don't eat too much Montbéliard saussages\n";
open (my $output, '>', 'RouterNetwork.txt') || die ('Vous ne pouvez pas créer le fichier "RouterNetwork.txt"');
while( <$conf> ) { # the current line is stored in $_
print $output "$1\t$2\n" if /(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}\/\d{1,2}).*\b(\d+)\?/;
}
close $output;
close $conf;
Note the word boundary before the number to be sure to obtain the whole number and not the last digit only.
The pattern can also be shorten to: /([\d.]{7,15}\/\d\d?).*?(\d+)\?/
Take care to not use old school programming style and look at perl current practises. (use strict and warnings systematically)
Note that with log files, a fields approach (split the line by whitespaces) is sometimes more handy.