Fill down empty values with conditions in SAS - sas

Question

How do I fill down empty values for different groups.
My data looks like:
id visit status var reason
1 1 Done x1
1 1 Done x2
1 1 Done x3
1 2 Not Done x1 text1
1 2 Not Done x2
1 2 Not Done x3
1 3 Done x1
1 3 Done x2
1 3 Done x3
2 1 Not Done x1 text2
2 1 Not Done x2
2 1 Not Done x3
2 2 Done x1
2 2 Done x2
2 2 Done x3
2 3 Done x1
2 3 Done x2
2 3 Done x3
The output should be like this
id visit status var reason
1 1 Done x1
1 1 Done x2
1 1 Done x3
1 2 Not Done x1 text1
1 2 Not Done x2 text1
1 2 Not Done x3 text1
1 3 Done x1
1 3 Done x2
1 3 Done x3
2 1 Not Done x1 text2
2 1 Not Done x2 text2
2 1 Not Done x3 text2
2 2 Done x1
2 2 Done x2
2 2 Done x3
2 3 Done x1
2 3 Done x2
2 3 Done x3
I think this is a quite simple problem, but for now, I haven't been able to resolve it. Any help would be greatly appreciated!

Answer 1

This is a simple task utilising the first.variable functionality that exists in a data step when a by statement is used.
Essentially I've created a new variable that is assigned the value of Reason whenever a new visit is encountered. The retain statement ensures that the new variable value is copied for all subsequent rows where the Id and Visit do not change. Then I just delete the original Reason variable and rename the new one.
data have;
infile datalines dsd;
input id visit status &$ var $ reason $;
datalines;
1, 1, Done, x1,,
1, 1, Done, x2,,
1, 1, Done, x3,,
1, 2, Not Done, x1, text1,
1, 2, Not Done, x2,,
1, 2, Not Done, x3,,
1, 3, Done, x1,,
1, 3, Done, x2,,
1, 3, Done, x3,,
2, 1, Not Done, x1, text2,
2, 1, Not Done, x2,,
2, 1, Not Done, x3,,
2, 2, Done, x1,,
2, 2, Done, x2,,
2, 2, Done, x3,,
2, 3, Done, x1,,
2, 3, Done, x2,,
2, 3, Done, x3
;
run;
data want;
set have;
retain reason_new;
by id visit;
if first.visit then reason_new=reason;
drop reason;
rename reason_new = reason;
run;