coldfusion get API token from salesforce - invalid grant - coldfusion

Question

I'm having a terrible time...I am trying to get coldfusion to get a token from salesforce, but I am stuck on the following error
{"error":"invalid_grant","error_description":"authentication failure"}
ive tried cfscript
local.http = new Http(url='https://test.salesforce.com/services/oauth2/token',method='post');
local.http.addParam(type='header',name='content-type', value='application/x-www-form-urlencoded');
local.http.addParam(type='formField',name='grant_type', value='password');
local.http.addParam(type='formField',name='client_id', value='client_id');
local.http.addParam(type='formField',name='client_secret', value='client_password_string');
local.http.addParam(type='formField',name='username', value='user#email.com');
local.http.addParam(type='formField',name='password', value='userspassword');
local.http.addParam(type='formField',name='format', value='json');
local.httpSendResult = local.http.send();
rc.httpResult = httpSendResult.getPrefix();
ive tried cfhttp tags
<cfhttp url="https://test.salesforce.com/services/oauth2/token" method="POST">
<cfhttpparam type="header" name="Content-Type" value="application/x-www-form-urlencoded" />
<cfhttpparam type="formField" name="grant_type" value="password" />
<cfhttpparam type="formField" name="client_id" value="client_id" />
<cfhttpparam type="formField" name="client_secret" value="client_password_string" />
<cfhttpparam type="formField" name="username" value="user#email.com" />
<cfhttpparam type="formField" name="password" value="userspassword" />
</cfhttp>
<cfset rc.result = cfhttp.fileContent />
however the same exact call executed by cUrl on my local machine works perfectly fine
curl -d "grant_type=password"
-d "client_id=client_id"
-d "client_secret=client_secret_string"
-d "username=user#email.com.dev"
-d "password=userpassword" https://test.salesforce.com/services/oauth2/token
ive made sure that my ip range is whitelisted, my ip relaxation is set to relax, allusers may self authorize, ive tried different username and password parameters, all i get is the same error about invalid grants
any help is very appreciated

Answer 1

I am not able to comment, so I have to answer :) But this is really just a suggestion. When you use <cfhttpparam type="formfield">, by default ColdFusion URL encodes that for you. ColdFusion will encode the characters ~, ., -, and _, but it should not actually do that according to the RFC 3986 spec (see https://en.wikipedia.org/wiki/Percent-encoding), since they are unreserved characters. If your formfields contain those characters (and I suspect they do since your example shows an email address), it is possible that those characters being encoded incorrectly is what is causing the authentication failure.
As a quick test you could add encoded="false" to your <cfhttpparam> tags and then url encode their values yourself using either encodeForUrl() or urlEncodedFormat() (depending on your version of ColdFusion), and then undo the incorrect encoding:
<cfhttpparam type="formField" encoded="false" name="username" value="#replacelist(urlEncodedFormat('user#email.com'), '%2D,%2E,%5F,%7E', '-,.,_,~')#">

Answer 2

Below is some CFScript code pulled out of a CFC I created for accessing salesforce. (won't run as is, but the logic is there - sorry it was too much code to copy the complete thing). Hoping it will help.
I'm using predominantly the same approach as you, but you might want to steal some of the specific settings (charset, content type, accept).
I've faked the values in the loginCredentials struct, but they are roughly the same kind of format (to compare with your own).
This runs fine for us on Railo. Maybe also check that it's not a SSL issue - do you need to add the SSL certs into Coldfusion so it can talk to Salesforce?
variables.sfAuthDomain = "https://login.salesforce.com";
variables.authServiceURL = variables.sfAuthDomain & "/services/oauth2/token";
variables.accessToken = "xxxxx" // The access token returned by SF, used on future logins
variables.loginCredentials = {
"grant_type": "password",
"client_id": "3MVG9Fkjshdkfjvshd ckjfhjkch.blkjlkjlkjkljl.wkjhgkjhkjhds.mVk84TRzhm_pXxK6_786786",
"client_secret": "3887687686868668727",
"username": "huge.duck#monkey.com.icom.icomqa",
"password": "Bungerloo!PPkjhj324ij45bQGyymmd"
};
/**
* MAKE SERVICE CALL
* Makes HTTP service call
**/
public Struct function makeServiceCall(String serviceUrl, String method="GET", Boolean sfAuth=true, Struct headers={}, Struct formFields) {
var httpService = new http(); // create new http service
var httpResponse = {};
var fieldName = "";
var bodyData = "";
/* set attributes using implicit setters */
httpService.setMethod(arguments.method);
httpService.setCharset("utf-8");
httpService.setUrl(Trim(arguments.serviceURL));
httpService.setTimeOut(variables.timeoutValue);
/* add httpparams using addParam() */
for(fieldName in arguments.headers) {
httpService.addParam(type="header", name="#fieldName#", value="#arguments.headers[fieldName]#");
}
if(arguments.sfAuth){
httpService.addParam(type="header", name="Authorization", value="OAuth #variables.accessToken#");
}
if(StructKeyExists(arguments, "formFields")) {
loop collection="#arguments.formFields#" item="fieldName" {
bodyData = ListAppend(bodyData, "#fieldName#=#formFields[fieldName]#", "&");
}
}
if(bodyData is not "") {
httpService.addParam(type="body", name="post", encoded="no", value="#bodyData#");
}
/* make the http call to the URL using send() */
httpResponse = httpService.send().getPrefix();
//dump(httpResponse, false, "modern", "", 500, "httpResponse");
return httpResponse;
}
httpResponse = makeServiceCall(
serviceUrl = serviceURL,
method = "POST",
sfAuth = false,
headers = {
"Content-Type": "application/x-www-form-urlencoded",
"accept": "text/json"
},
formFields = loginCredentials
);

Answer 3

Ended up changing my coldfusion server to use TLS 1.2, as TLS 1.0 was deprecated for use by salesforce. Hope my answer and the helpful answers given on this post help someone else

Answer 4

Your password formfield value is contain only password, so that kind of error is shown:
({"error":"invalid_grant","error_description":"authentication failure"}).
That must be contain(password and security token).
<cfhttpparam type="formField" name="password" value="#arguments.password##arguments.Security_token#"/>