Error in inputting dates - sas

Question

I am trying to input dates using datalines but it is not working:
data demographic;
input Subj #5 DOB mmddyy6. #16 Gender $ Name $;
format dob ddmmyy10.;
datalines;
001 10/15/1960 M Friedman
002 08/01/1955 M Stern
003 12/25/1988 F McGoldrick
005 05/28/1949 F Chien
;
run;
What seems to be the problem?

Answer 1

When you include the format on the input statement it expects exactly that format/length. In this case, you've incorrectly specified the date informat. It's a 10 character variable and you're trying to use only 6. If you create an INFORMAT statement and remove the specifications from the INPUT statement it will work fine.
data demographic;
informat subj $3. dob mmddyy10. gender $1. name $16.;
input Subj DOB Gender Name ;
format dob ddmmyy10.;
datalines;
001 10/15/1960 M Friedman
002 08/01/1955 M Stern
003 12/25/1988 F McGoldrick
005 05/28/1949 F Chien
;
run;

Answer 2

You told SAS to start reading DOB at column 5 and read only 6 characters. But your data values for DOB include slashes and century digits on the year, so they will take up to 10 characters.
If your input stream is fixed format then you could just change the width on your informat to 10 instead of 6. So if your data field positions are fixed your input statement might look like this. (Personally I like to format dates using YMD order to avoid confusion when working with people in both the US (MDY) and EU (DMY).)
data demographic;
input Subj 1-3 #5 DOB MMDDYY10. Gender $16 Name $18-27;
format dob YYMMDD10.;
datalines;
001 10/15/1960 M Friedman
002 08/01/1955 M Stern
003 12/25/1988 F McGoldrick
005 05/28/1949 F Chien
;
Now if your input data are not in fixed column locations (and any missing values are represented by .) then you could read the data using list mode input instead. Use the : modifier before any informats on the input statement to insure that you are using list mode and not formatted mode. When SAS reads variable values in list mode it will ignore the width on the applicable informat and use the length of the current word being read instead. If you want to take advantage of the INPUT statement being the first place that your variables appear to define the variable's type and length then you could use $xx. informats on the input statement, just make sure to include : modifier. SAS will ignore the width when reading the data but since it is the first place you have referenced the variable SAS will use the width of the informat to help if guess how you wanted the variable defined.
data demographic;
input Subj DOB :MMDDYY. Gender :$1. Name :$10.;
format dob YYMMDD10.;
datalines;
001 10/15/1960 M Friedman
002 8/1/1955 M Stern
003 . F McGoldrick
005 5/28/1949 F Chien
;
Or instead you could define the variables explicitly using LENGTH or ATTRIB statements before using them in the INPUT statement. In that case you might want to just use a INFORMAT statement to tell SAS how to read DOB instead of including the informat in the INPUT statement. That can make the INPUT statement easier to write since you could use variable lists.
data demographic;
length Subj 8 DOB 8 Gender $1 Name $10 ;
informat dob mmddyy.;
format dob YYMMDD10.;
input subj -- name ;
datalines;
001 10/15/1960 M Friedman
002 8/1/1955 M Stern
003 . F McGoldrick
005 5/28/1949 F Chien
;