Fortran compile error 764 nesting error - fortran

Question

!subroutine No.10: to calculate positive capilary pressure required
subroutine Pcow_positive1(sigma_ow,R,alpha,b,teta_ow,Pcow_positive,r1,time)
implicit none
!dummy argument declarations
double precision,intent(in)::sigma_ow
double precision,intent(in)::R
double precision,intent(in)::alpha
double precision,intent(in)::b
double precision,intent(in)::teta_ow
double precision,intent(out)::Pcow_positive
double precision,intent(out)::r1
double precision::omega_eff
double precision::A_eff
double precision::beta
double precision::Pcow
double precision::r2
double precision::error
double precision::error1
double precision::abeta
integer,intent(out)::time
!calculate Pcow_positive
time=0
r1=R
700 if (time>1500) then
goto 950
else
abeta=((b*(sin(alpha)))/(r1))
if (abeta>1.0) then
goto 900
else
end if
beta=asin(abeta)
time=time+1
A_eff=(((R**2.0)/(2.0*tan(alpha))))-(((r1)*(b)*(sin(alpha+beta)))/2.0) &
+(((((r1)**2)*(beta))/2.0))
omega_eff=(((((R)*(1.0/(tan(alpha))))-b)*(cos(teta_ow)))+((r1*beta)))
Pcow=(((sigma_ow)*(omega_eff))/(A_eff))
r2=(sigma_ow)/(Pcow)
error=abs(r2-r1)
error1=abs((sigma_ow/r2)-(sigma_ow/r1))
if (error<=0.01 .or. error1<=0.01) then
goto 800
else
r1=r2
goto 700
end if
800 r1=r2
Pcow_positive=Pcow
goto 1000
900 r1=(b*(sin(alpha)))
Pcow_positive=(sigma_ow)/(r1)
goto 1000
950 r1=(sigma_ow)/(0.0005)
Pcow_positive = 0.0005
1000 end subroutine Pcow_positive1
When I compile the code I get an error message at end subroutine Pcow_positive1 which I cannot fix.
Any help is greatly appreciated.
Compile error: error 764 - Nesting error - the block IF construct on line 4079 has not been terminated
line 4079 :
700 if (time>1500) then

Answer 1

There's a few problems with this code. The most immediate is that you are missing an end if. You don't see this because, as noted, you haven't consistently indented your code. Your editor should do this automatically for you and would make spotting this very easy to spot - I cut and paste your code into emacs, auto indented the subprogram and the problem was clear. However where the endif should go was not, and so in what follows I've had to guess where to put it, and as you haven't supplied a complete program it's difficult to test what I have done, but even if I have made a mistake I hope the ideas behind what I have done is clear.
Anyway the next issue is DON'T USE GOTO! There's very rarely any need and it usually leads, as here, to confusing, so called spaghetti code. Instead learn your control structures and use them. A do loop and a few EXITs will tidy this up nicely.
Next all your constants are single precision. Yet all your variables are double precision. As a result your routine will not be as precise as you want. In a double precision code if you see 1.0 with no other qualifier there is almost always something wrong.
So how to fix that. Well Double Precision is so 1980s, so instead learn about kinds, covered in detail any number of times on stackoverflow, or look in your Fortran book (you do have one?) and use them. Anyway putting this all together with the above caveat (and also that I've only spent 5 mins on this, in practice I would tidy further but breakfast is calling) I would write your routine something like
!subroutine No.10: to calculate positive capilary pressure required
Subroutine Pcow_positive1(sigma_ow,R,alpha,b,teta_ow,Pcow_positive,r1,time)
Implicit None
!dummy argument declarations
Integer, Parameter :: wp = Selected_real_kind( 12, 70 )
Real( wp ),Intent(in)::sigma_ow
Real( wp ),Intent(in)::R
Real( wp ),Intent(in)::alpha
Real( wp ),Intent(in)::b
Real( wp ),Intent(in)::teta_ow
Real( wp ),Intent(out)::Pcow_positive
Real( wp ),Intent(out)::r1
Real( wp )::omega_eff
Real( wp )::A_eff
Real( wp )::beta
Real( wp )::Pcow
Real( wp )::r2
Real( wp )::error
Real( wp )::error1
Real( wp )::abeta
Integer,Intent(out)::time
!calculate Pcow_positive
time=0
r1=R
Do
If (time>1500) Then
r1=(sigma_ow)/(0.0005_wp)
Pcow_positive = 0.0005_wp
Exit
End If
abeta=((b*(Sin(alpha)))/(r1))
If (abeta>1.0_wp) Then
r1=(b*(Sin(alpha)))
Pcow_positive=(sigma_ow)/(r1)
Exit
Else
End If
beta=Asin(abeta)
time=time+1
A_eff=(((R**2.0_wp)/(2.0_wp*Tan(alpha))))-(((r1)*(b)*(Sin(alpha+beta)))/2.0_wp) &
+(((((r1)**2)*(beta))/2.0_wp))
omega_eff=(((((R)*(1.0_wp/(Tan(alpha))))-b)*(Cos(teta_ow)))+((r1*beta)))
Pcow=(((sigma_ow)*(omega_eff))/(A_eff))
r2=(sigma_ow)/(Pcow)
error=Abs(r2-r1)
error1=Abs((sigma_ow/r2)-(sigma_ow/r1))
r1=r2
If (error<=0.01_wp .Or. error1<=0.01_wp) Then
Pcow_positive=Pcow
Exit
End If
End Do
End Subroutine Pcow_positive1