SAS proc genmod with clustered, multiply imputed data - sas

Question

I am seeking to obtain risk ratio estimates from multiply imputed, cluster-correlated data in SAS using log binomial regression using SAS Proc Genmod. I've been able to calculate risk ratio estimates for the raw (non-MI) data, but it seems that the program is hitting a snag in generating an output dataset for me to read into Proc Mianalyze.
I am including a repeated subjects statement so that SAS will use robust variance estimation. Without the "repeated subjects" statement, the ODS Output statement seems to work just fine; however, once I include the "repeated subjects" statement, I receive an warning message that my output dataset was not generated.
I am open to other approaches and suggestions to generate risk ratio estimates using this data if the genmod/mianalyze combination is not appropriate, but would like to see if I can get this to work! I would prefer SAS, if possible, due to license access issues to other programs, like Stata and SUDAAN. My code is below, where "seroP" is my binomial outcome, "int" is the binomial independent variable of interest (intervention received vs not received), "tf5" is a binomial covariate, age is a continuous covariate, and village specifies the cluster:
Proc GenMod data=sc.wide_mip descending ; by _Imputation_;
Class int (ref='0') tf5 (ref='0') village /param=ref ;
weight weight;
Model seroP= int tf5 age /
dist=bin Link=logit ;
repeated subject=village/ type=unstr;
estimate 'Beta' int 1 -1/exp;
ods output ParameterEstimates=sc.seroP;
Run;
proc mianalyze parms =sc.seroP;
class int tf5 ;
modeleffects int tf5 age village ;
run;
Thank you for your help!

Answer 1

The short answer is to add an option “PRINTMLE” at the end of the “Repeated” statement. But the code you posted here may not produce what you actually want. So, following is a longer answer:
1.The program below is based on SAS 9.3 (or newer versions) for Windows. If you are using an older version, the coding might be different.
2.For PROC MIANALYZE, three ODS tables from PROC GENMOD are required instead of one, namely, 1) the parameter estimate table (_est); 2) the covariance table (_covb); and 3) the parameter index table (parminfo). The first line of the PROC MIANALYZE statement should look like:
PROC MIANALYZE parms = ~_est covb = ~_covb parminfo=parminfo;
whereas ~_est refers to an ODS parameter table, and ~_covb refers to an ODS covariance table.
There are different types of ODS parameter estimate and covariance tables. The sign “~” should be replaced by a specific set of ODS tables, which will be discussed in the following part.
3.From PROC GENMOD, three different sets of ODS parameter and covariance tables can be generated.
3a) The first set of tables is from a non-repeated model (i.e., without the “repeated” statement). In your case, it looks like:
Proc GenMod data=sc.wide_mip descending ; by _Imputation_;
…
MODEL seroP= int tf5 age/dist=bin Link=logit COVB; /*adding the option COVB*/
/*repeated subject=village/ type=unstr;*/
/*Note that the above line has been changed to comments*/
…
ODS OUTPUT
/*the estimates from a non-repeated model*/
ParameterEstimates=norepeat_est
/*the covariance from a non-repeated model*/
Covb = nonrepeat_covb
/*the indices of the parameters*/
ParmInfo=parminfo;
Run;
Of note, 1) the option COVB is added in the MODEL statement, so as to obtain the ODS covariance table. 2) The “Repeated” statement is put as comments. 3) The “~_est” table is named “nonrepeat_est”. Similarly, the table “~_covb” is named “nonrepeat_covb.
3b) The second set of tables contains model-based estimates from a repeated model. In your case, it looks like:
…
MODEL seroP= int tf5 age/dist=bin Link=logit;
REPEATED subject=village/ type=un MODELSE MCOVB;/*options added*/
…
ODS OUTPUT
/*the model-based estimates from a repeated model*/
GEEModPEst=mod_est
/*the model-based covariance from a repeated model*/
GEENCov= mod_covb
/*the indices of the parameters*/
parminfo=parminfo;
Run;
In the “REPEATED” statement, the option MODELSE is to generate model-based parameter estimates, and MCOVB is to generate the model based covariance. Without these options, the corresponding ODS tables (i.e., GEEModPEst and GEENCov) will not be generated. Note that the ODS table names are different from the previous case. In this case, the tables are GEEModPEst and GEENCov. In the previous case (a non-repeated model), the tables were ParameterEstimates and COVB. Here, the ~_est table is named “mod_est”, standing for the model-based estimates. Similarly, the ~_covb table is named “mod_covb”. The ParmInfo table is the same as in the previous model.
3c) A third set contains empirical estimates, also from a repeated model. The empirical estimates are also called ROBUST estimates. Sounds like the results here are what you want. It looks like:
…
MODEL seroP= int tf5 age/dist=bin Link=logit;
REPEATED subject=village/ type=un ECOVB;/*option changed*/
…
ODS OUTPUT
/*the empirical(ROBUST) estimates from a repeated model*/
GEEEmpPEst=emp_est
/*the empirical(ROBUST) covariance from a repeated model*/
GEERCov= emp_covb
/*the indices of the parameters*/
parminfo=parminfo;
Run;
As you may have noticed, in the “Repeated” statement, the option is changed to ECOVB. That way, the empirical covariance table will be generated. Nothing is required to generate the empirical parameter estimates, as they are always produced by the procedure. The ParmInfo table is the same as in the previous cases.
4.Putting together, actually you can generate the three sets of tables at the same time. The only thing is that, an option “PRINTMLE” should be added, so as to generate estimates from a non-repeated model when repeated terms are in place. The combined program looks like the following:
Proc GenMod data=sc.wide_mip descending ; by _Imputation_;
Class int (ref='0') tf5 (ref='0') village /param=ref ;
weight weight;
Model seroP= int tf5 age /
dist=bin Link=logit COVB; /*COVB to have non-repeated model covariance*/
repeated subject=village/ type=UN MODELSE PRINTMLE MCOVB ECOVB;/*all options*/
estimate 'Beta' int 1 -1/exp;
ODS OUTPUT
/*the estimates from a non-repeated model*/
ParameterEstimates=norepeat_est
/*the covariance from a non-repeated model*/
Covb = nonrepeat_covb
/*the indices of the parameters*/
ParmInfo=parminfo
/*the model-based estimates from a repeated model*/
GEEModPEst=mod_est
/*the model-based covariance from a repeated model*/
GEENCov= mod_covb
/*the empirical(ROBUST) estimates from a repeated model*/
GEEEmpPEst=emp_est
/*the empirical(ROBUST) covariance from a repeated model*/
GEERCov= emp_covb
;
Run;
/*Analyzing non-repeated results*/
PROC MIANALYZE parms = norepeat_est covb = norepeat_covb parminfo=parminfo;
class int tf5 ;
modeleffects int tf5 age village ;
run;
/*Analyzing model-based results*/
PROC MIANALYZE parms = mod_est covb = mod_covb parminfo=parminfo;
class int tf5 ;
modeleffects int tf5 age village ;
run;
/*Analyzing empirical(ROBUST) results*/
PROC MIANALYZE parms = emp_est covb = emp_covb parminfo=parminfo;
class int tf5 ;
modeleffects int tf5 age village ;
run;
Hopefully it helps. For further reading:
SAS proc genmod with clustered, multiply imputed data
http://www.ats.ucla.edu/stat/sas/v8/mianalyzev802.pdf
http://analytics.ncsu.edu/sesug/2006/ST12_06.PDF
Allison, Paul D. Logistic Regression Using SAS®: Theory and Application, Second Edition (page 226-234). Copyright © 2012, SAS Institute Inc.,Cary, North Carolina, USA.