Equivalent of +=/*= operator in sas - sas

Question

Does SAS has an equivalent of += or *= expression just like the C++ language?
For instance I have a list of variables X1-X10 and I would like to define a variable Final in the following form:
%let name= X1 X2 X3 X4 X5 X6 X7 X8 X9 X10
%Macro Total;
%Do i=1 %to %sysfunc(countw(&name., " "));
%Let K= %sysfunc(scan(&name., %i., " "));
Final *= K;
%End;
%Mend;

Answer 1

Not sure why you are trying to do it with macro code. If you want to manipulate data use a data step.
There is a the sum statement.
var + (expression) ;
For example if I wanted to calculate a cumulative sum of a variable I could do this:
data want;
set have ;
cum_X + X;
run;
But there is no similar statement to do aggregate products. If you wanted to to make a similar thing using multiplication would need to spell out the RETAIN statement and use normal assignment statement.
data want;
set have ;
retain prod_x 1 ;
prod_x = prod_x * x;
run;
If you actually just have a macro variable with a list of variable names and you ant to operate strictly on a single observation at a time then you can just use text manipulation to convert the list into the calculation you want.
%let namelist = vara varb vard varx vary varz ;
data want ;
set have ;
sum = %sysfunc(tranwrd(&namelist,%str( ),+)) ;
product = %sysfunc(tranwrd(&namelist,%str( ),*)) ;
run;
If you want more control then define an array and loop over it. Here is an example using the DO OVER syntax. (SAS is trying to get rid of DO OVER so you can also do the same thing using an index variable and typing more characters in your array references.)
data want;
set have ;
array x &namelist ;
sum=0;
product=1;
do over x ;
if not missing(x) then do ;
sum= sum+x ;
product = product*x ;
end;
end;
run;