How to add all .pri files inside a directory - c++

Question

I've searched quite thoroughly, but couldn't find a way to get all the folders inside a directory. I have the following qt project structure
first/
second/
- second.pri
third/
- third.pri
...
first.pri
I want to include all the pri files inside the first.pri file. I can do
include($$PWD/second/second.pri)
include($$PWD/third/third.pri)
...
But the problem is there could be many sub directories added in the future and I want to automatically include all the pri files. I've tried
FILES = $$files($$PWD/*/*.pri)
for(FILE, FILES) {
include($$FILE)
}
But this does not find the folders inside 'first' folder. $$files documentation allows specification of recursive, but it does not descend into subdirectories. How do I achieve it?

Answer 1

The following QMAKE function lists recursively all the files below a directory:
# - Function that list all files below a directory
defineReplace(list_recursively) {
FILES = $$files($$1)
RESULT =
for(var, $$list($$FILES)) {
exists($$var)
{
RESULT *= $$find(var, .*\.pri)
RESULT *= $$list_recursively($$var/*)
}
}
return($$RESULT)
}
# - Define the base directory
DIR = $$PWD/*
# - Test the function
temp_dir = $$list_recursively($$DIR)
# - Output the result
for(var, $$list($$temp_dir)) {
message($$var)
}
In the list_recursively function, it is possible to filter only those files with a specific extension, for example .pri. This is not even required if your project structure contain only .pri file.
Note: QMake does not work correctly with white spaces, it is usually a good idea to avoid them.
EDITED:
Added a filter for .pri files.