How to store Id values from response in soapui - web-services

Question

I have to add 3 records in Soap UI request as below:
<soapenv:Envelope>
<soapenv:Header/>
<soapenv:Body>
<wor:AddValues>
<wor:User>
<data:userid>${Properties1#UserID}</data:userid>
</wor:User>
<data:ValuesList>
<data:Value>
<data:Desc>${Properties1#Desc1}</data:Desc>
<data:Details>${Properties1#Detail1}</data:Details>
</data:Value>
<data:Value>
<data:Desc>${Properties1#Desc2}</data:Desc>
<data:Details>${Properties1#Detail2}</data:Details>
</data:Value>
<data:Value>
<data:Desc>${Properties1#Desc3}</data:Desc>
<data:Details>${Properties1#Detail3}</data:Details>
</data:Value>
</data:ValuesList>
</wor:AddValues>
</soapenv:Body>
</soapenv:Envelope>
After completion this will generate unique ID for each value added.
The response would look like below:
<s:Envelop>
<s:Body>
<AddUserValueResult>
<a:ValuesList>
<a:Value>
<a:Id>2501</a:Id>
<a:Desc>Desc1</a:Desc>
<a:Details>Detail1</a:Details>
</a:Value>
<a:Value>
<a:Id>2502</a:Id>
<a:Desc>Desc2</a:Desc>
<a:Details>Detail2</a:Details>
</a:Value>
<a:Value>
<a:Id>2503</a:Id>
<a:Desc>Desc3</a:Desc>
<a:Details>Detail3</a:Details>
</a:Value>
</a:ValuesList>
</AddUserValueResult>
</s:Body>
</s:Envelop>
Using groovy script I want to use the properties Desc1 & Details1,
compare it with response and if it matches then get the ID of that record and store the ID generated in response in another Property Id1.
Continue same for other two records.
Can you please help me to achieve this?
Thanks in Advance!

Answer 1

Here is what to be done one in order to be able to compare the data from request and response:
Create an object model, so that both request and response can be transformed into list of objects, and then compare.
Extract the required data from request / response and build the object list
Need to consider a fact that the both request and response has list of data / values, and it may come in any random order. So, the object should be comparable.
In this case, Script Assertion can be used for comparison without any additional test step. So, add the script assertion to your Soap Request test step.
Here is the script:
/**
* This is script assertion
* Reads both request and response
* Builds the object list, so that both can be compared
**/
//Object Model, req / resp is transformed into this model
#groovy.transform.Canonical
#groovy.transform.Sortable
class Model {
String desc
String details
}
//Closure to retrieve the data element of user choice from xml
def searchData = { data, element ->
def parsedData = new XmlSlurper().parseText(data)
parsedData.'**'.findAll{it.name() == element}
}
//Closure to build the object list of above provided Model class
def buildData = { list, desc, details ->
def objects = []
list.each { item ->
objects << new Model(desc: item."$desc", details: item."$details")
}
objects
}
//Assert if the request and response are non-empty
assert context.rawRequest, "Request is empty or null"
assert context.response, "Response is empty or null"
//Get the Value elements from both request and response
def reqValues = searchData(context.rawRequest, 'Value')
def respValues = searchData(context.response, 'Value')
//Build the Model object list for both request and response and sort them to be able to compare
def reqObjectList = buildData(reqValues, 'Desc', 'Details' ).sort()
def resObjectList = buildData(respValues, 'Desc', 'Details' ).sort()
//Log the above
log.info "Value objects from request: ${reqObjectList.toString()}"
log.info "Value objects from response: ${resObjectList.toString()}"
//Finally, compare the data from both request and response
assert reqObjectList == resObjectList, "Data is not matching"
//Now set the Ids at test case level custom properties
respValues.eachWithIndex { value, index ->
log.info "Id${index+1} : ${value.Id as String}"
context.testCase.setProperty("Id${index+1}", "${value.Id as String}")
}
Now you can use ${#TestCase#Id1} etc.. where ever you need those values.
Note that : it will save those ids if an only if both ValuesList are matched.
You may quickly try it out from Demo till comparing request and response valueslist