chicken scheme srfi-64 test-error problems - unit-testing

Question

I am using chicken scheme version 4.9.0.1 and am working on a
unit test suite using the unit test package srfi-64.
I am having trouble with test-error in this unit test package.
A minimal example of the problem:
(require-extension srfi-64)
(test-begin "error testing")
(define (exn-tester)
(error "What does srfi-64 want?"))
(test-error "the exn-tester" 'exn (exn-tester))
(test-end)
Results in the report:
%%%% Starting test error testing
Group begin: error testing
Test begin:
test-name: "the exn-tester"
Test end:
result-kind: fail
actual-error: #<condition: (exn)>
expected-error: exn
Group end: error testing
# of unexpected failures 1
The problem is clearly in my test-error because I don't know how
to represent the exception in a form that test-error understands.
I've tried multiple variations on the actual-error as listed,
but to no success.
Specifically, what should I code for the expected-error in the
test-error call?

Answer 1

The SRFI spec itself basically says "it's implementation-dependent", but after a look at the code it seems you can simply pass it a predicate:
(require-extension srfi-64)
(test-begin "error testing")
(define (exn-tester)
(error "What does srfi-64 want?"))
(test-error "the exn-tester" (condition-predicate 'exn) (exn-tester))
(test-end)
Please note that in the CHICKEN community, the test egg is the facto testing egg. However, it currently has no way to test for a specific exception type. I once wrote this macro for the Postgres egg's test suite:
(define-syntax test-error*
(syntax-rules ()
((_ ?msg (?error-type ...) ?expr)
(let-syntax ((expression:
(syntax-rules ()
((_ ?expr)
(condition-case (begin ?expr "<no error thrown>")
((?error-type ...) '(?error-type ...))
(exn () (##sys#slot exn 1)))))))
(test ?msg '(?error-type ...) (expression: ?expr))))
((_ ?msg ?error-type ?expr)
(test-error* ?msg (?error-type) ?expr))
((_ ?error-type ?expr)
(test-error* (sprintf "~S" '?expr) ?error-type ?expr))))
To be used as follows:
(test-error* "Result value error for out of bounds row"
(exn postgresql bounds)
(value-at (query conn "SELECT NULL") 0 1))
The (exn postgresql bounds) tells the test to accept a composite condition (refer to SRFI-12 for more info) of the types exn, postgresql and bounds. It can have other types, but in this example, these three must be present for the test to pass.

Answer 2

With your tips, the following works well enough:
(require-extension test)
test-begin "error-testing")
(define (exn-tester)
(error "What does srfi-64 want?"))
(test-error (exn-tester))
(test-end "error-testing")
Attempts to use your define-syntax resulted in "unbound variable: exn".
Perhaps I require additional extension to use this?
However, your define-syntax will warrant future attention. I am only getting started in Scheme and, having a test driven background, am most interested in my code being the very best.