SAS catx function removes spaces - sas

Question

I have a dataset which has 1 column and n rows like this:
Dataset1:
Column1
--------
AAA AAA
BBB BBB
CCC CCC
DDD DDD
EEE EEE
I want to make from this data 1 row like:
"AAA AAA"n "BBB BBB"n "CCC CCC"n "DDD DDD"n "EEE EEE"n
I will make this in macro.
I used like catx function. But the function removes spaces from data..
I used do loop like this :
.
.
.
.
data _NULL_;
if &I^=1 then do;
frstclmn=&frstclmn||""""||"&clmn"||""""||"n ";
end;
run;
.
.
.
But I couldn't assing a variable in do lop in data statement with itself.
How can I do ? Thanks
Edit:
%MACRO result;
data _NULL_;
set &LIB_NAME..column_list;
retain namelist;
length namelist $5000;
namelist=catx(' ',namelist,cats('"',name,'"n'));
run;
---how can I use "namelist" variable here ? out of data statement.---
%MEND result;
This code runs perfectly. Now I want to use this namelist variable out of this data statement. If I print like this %put &namelist=; It show wrong result in macro. I want to use this variable result in macro other statement.

Answer 1

It's not clear to me what output you seek. Perhaps this will give you some hints.
data names;
input name $32.;
cards;
AAA AAA
BBB BBB
CCC CCC
DDD DDD
EEE EEE
;;;;
run;
proc sql noprint;
select nliteral(name) into :namelist separated by ' ' from names;
quit;
run;
%put NOTE: &=namelist;
NOTE: NAMELIST="AAA AAA"N "BBB BBB"N "CCC CCC"N "DDD DDD"N "EEE EEE"N

Answer 2

The sql method data _null_ shows above is the better method, but if you're going to do it in data step, use ' ' as your delimiter.
data _NULL_;
set sashelp.class;
retain namelist;
length namelist $500;
namelist=catx(' ',namelist,cats('"',name,'"n'));
put namelist=;
run;
Of course you could use quote, or nliteral, both to better effect.
data _NULL_;
set sashelp.class;
retain namelist;
length namelist $500;
namelist=catx(' ',namelist,nliteral(name));
put namelist=;
run;