multiline textbox validation ms access - regex

Question

Hi I am pretty new to Ms Access and I could use some of your expertise to advise:
I would like to validate the text of a multiline textbox, so that the user can only enter 2 capital letters - 7 numbers - semi-colon - new line. As an example, the textbox would look like this (but with each entry on a new line, since I have it so that enter makes a new line in the textbox
AB1234567; SE0001848; SE0019591; RE0010599; etc.
I think this is too complex for a validation rule. I also think it's too complex for an input mask. I started looking into RegEx to validate the text but I am hungup on how to have the code evaluate each new line in the multiline textbox so that the entire textbox is evaluated. Do i need to do a loop of some sort?
Ultimately, I would like the user to get a message box when they enter their text incorrectly that blocks the entry from being added to the record and also explains to the user that they need to modify their entry so that it is valid.

Answer 1

I think your idea of RegEx is the easiest but you'll need to add a reference (see code).
This should do what you want (just replace Text14 with your text control)
Note - I removed the CANCEL=TRUE because that wipes out the users data. The best route woul dbe to make sure the text box is UNBOUND - then if valid you would update the actual field if the RegExp is validated for all lines
Private Sub Text14_BeforeUpdate(Cancel As Integer)
' Requires reference to "Microsoft VBScript Regular Expressions 5.5"
' Under Tools | References
' Add Reference to "Microsoft VBScript Regular Expressions 5.5"
' 2 Capital Letters followed by 7 digits and ";'
Const VALID_LINE As String = "[A-Z]{2}[\d]{7};"
Dim regEx As New RegExp
Dim strData As String ' Read in textbox
Dim varLines As Variant ' Use this to hold lines of text
Dim intNumLines As Integer
Dim intLine As Integer
Dim strLine As String
With regEx
.Global = True
.Multiline = False
.IgnoreCase = False
.Pattern = VALID_LINE
End With
' Replace Text14 with your text box control name
strData = Text14.Value ' Get Data from Text box
' Split data into lines using Carriage Return Line Feed delimiters
varLines = Split(strData, vbCrLf)
' Go thru all lines to check for data issue
intNumLines = UBound(varLines)
For intLine = 0 To intNumLines
strLine = varLines(intLine)
If Not regEx.Test(strLine) Then
MsgBox "Problem with Line #" & (intLine + 1)
' Cancel - if you want to wipe out data
' Cancel = True
Exit Sub
End If
Next
MsgBox "Data Looks Good: All " & intNumLines & " Lines"
End Sub