Selecting a random column from a group of columns of interest - sas

Question

I am trying to come up with code that will select a random column from a group of columns on interest. The group of columns will change depending on the values in the columns for each observation. Each observation is a subject.
Let me explain to be more clear:
I have 8 columns, names V1-V8. Each column has 3 potential responses ('Small','Medium','High'). Due to certain circumstances in our project, I need to "combine" all this information into 1 column.
Key factor 1: We only want the columns per subject where he/she selected 'High' (lots of combinations here). This is what I refer to when I say the columns of interest changes per subject.
Key factor 2: Once I have identified the columns where 'High' was selected for the subject, select one of the columns at random.
At the end, I need a new variable (New_V) with values V1-V8 (NOT 'Small','Medium','High') indicating which column was selected for each subject.
Any advice would be great. I have tried ARRAYs and Macro variables but I can seem to tackle this the right way.

Answer 1

This method uses macro variables and a loop. There are three main steps: First, find all variables that are "high." Second, select a random value from 1 to the number of variables that are "high." Third, pick that variable and call it selected_var.
data temp;
input subject $ v1 $ v2 $ v3 $ v4 $ v5 $ v6 $ v7 $ v8 $;
datalines;
1 high medium small high medium small high medium
2 medium small high medium small high medium high
3 small high high medium small high medium high
4 medium medium high medium small small medium medium
5 medium medium high small small high medium small
6 small small high medium small high high high
7 small small small small small small small small
8 high high high high high high high high
;
run;
%let vars = v1 v2 v3 v4 v5 v6 v7 v8;
%macro find_vars;
data temp2;
set temp;
/*find possible variables*/
format possible_vars $20.;
%do i = 1 %to %sysfunc(countw(&vars.));
%let this_var = %scan(&vars., &i.);
if &this_var. = "high" then possible_vars = cats(possible_vars, "&this_var.");
%end;
/*create a random integer between 1 and number of variables to select from*/
rand = 1 + floor((length(possible_vars) / 2) * rand("Uniform"));
/*pick that one!*/
selected_var = substr(possible_vars, (rand * 2 - 1), 2);
run;
%mend find_vars;
%find_vars;

Answer 2

You're on the right track with arrays. The vname function will be helpful here. The want datastep shows how to do this (the rest just sets up example data):
proc format;
value smh
1='Small'
2='Medium'
3='High'
other=' '
;
quit;
data have;
call streaminit(5);
array v[8] $;
do _i = 1 to 1000;
do _j = 1 to 8;
__rand = ceil(1+rand('Binomial',.7,2));
v[_j] = put(__rand,smh6.);
end;
if whichc('High',of v[*]) = 0 then v8 = 'High'; *guarantee have one high;
output;
end;
drop _:;
run;
data want;
call streaminit(7); *arbitrary seed here, pick any positive number;
set have;
array v[8] ;
do until (v[_rand] = 'High'); *repeat this loop until one is picked that is High;
_rand = ceil(8*rand('Uniform'));
end;
chosen_v = vname(v[_rand]); *assign the chosen name to chosen_v variable;
drop _:;
run;
proc freq data=want;
tables chosen_v;
run;