Is there a way to simply transpose data in SAS - sas

Question

I'm a newbie to SAS. I am trying to document the table structure of the 50+ data sets and so I want to just take the top 5 rows from each data set and output it on console. However, since many of these data sets have many columns I would like to transpose them. I tried to use proc transpose but apparently it doesn't just flip the results and keeps dropping columns.
For example, the following code only produce results with MSGID and LINENO only...
proc print data=sashelp.smemsg;
run;
proc transpose data=sashelp.smemsg out=work.test;
run;
proc print data=work.test;
run;
Update:
I think it didn't work because SAS doesn't know how to "normalize" the data types after the transformation. I would like to something similar to this in R where all numbers became string.
> df <- data.frame(x=11:20, y=letters[1:10])
> df
x y
1 11 a
2 12 b
3 13 c
4 14 d
5 15 e
6 16 f
7 17 g
8 18 h
9 19 i
10 20 j
> t(df)
[,1] [,2] [,3] [,4] [,5] [,6] [,7] [,8] [,9] [,10]
x "11" "12" "13" "14" "15" "16" "17" "18" "19" "20"
y "a" "b" "c" "d" "e" "f" "g" "h" "i" "j"

Answer 1

To quickly look at the data in SAS dataset I normally just use a PUT statement and look at the log.
data _null_;
set have (obs=5);
put (_all_) (=/);
run;
If you just want to transpose the data then use PROC TRANSPOSE. You need to specify the variables or you will only get the numeric ones.
proc transpose data=have (obs=5) out=want ;
var _all_ ;
run;
proc print data=want ;
run;

Answer 2

Here is roughly how to do it.
Generate sample dataset having 25 rows, 6 numeric vars and 6 string vars
data sample;
array num_col_(6);
array str_col_(6) $;
do row_number = 1 to 25;
do col_number = 1 to 6;
num_col_(col_number) = round(ranuni(0),.01);
str_col_(col_number) = byte(ceil(ranuni(0)*10)+97);
end;
output;
end;
drop row_number col_number;
run;
Transpose data, keeping only 5 first rows
proc transpose data=sample(obs=5) prefix=row
out=sample_tr(rename=(_name_=column));
var num_col_: str_col_:;
/* You could also use keywords on the var statement */
* var _character_ _numeric_; * Lets you decide which type to show first;
* var _all_; * Keeps original order of variables;
run;
Show the results
proc print data=sample_tr noobs;
id column;
var row1-row5;
run;
Results
column row1 row2 row3 row4 row5
--------- ---- ---- ---- ---- ----
num_col_1 0.66 0.96 0.85 0.45 0.32
num_col_2 0.78 0.79 0.64 0.85 0.74
num_col_3 0.23 0.62 0.46 0.46 0.51
num_col_4 0.91 0.15 0.16 0.77 0.13
num_col_5 0.6 0.48 0.32 0.6 0.77
num_col_6 0.13 0.76 0.67 0.16 0.67
str_col_1 c i i i c
str_col_2 j k f f c
str_col_3 e g k h i
str_col_4 b h d k e
str_col_5 c h f e f
str_col_6 i b k i f