Using Saxon, increment or decrement the global variables in XSLT - xslt

Question

I want to use a counter to increment and decrement the value in XSLT. I am able to achieve this using Apache Xalan, but now I want to achieve the same using Saxon.
My XSLT script for Xalan looks like this:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:lxslt="http://xml.apache.org/xslt"
xmlns:result="http://www.example.com/results"
extension-element-prefixes="result">
<lxslt:component prefix="result" functions="incr dcr">
<lxslt:script lang="javascript">
var count = 0;
function incr() {
count++;
return count;
}
function dcr() {
count--;
return count;
}
</lxslt:script>
</lxslt:component>
<xsl:template match="/">
a)<xsl:value-of select="result:incr()"/>
b)<xsl:value-of select="result:incr()"/>
c)<xsl:value-of select="result:dcr()"/>
</xsl:template>
</xsl:stylesheet>
Expected output is:
a)1
b)2
c)1
------------------------- my use case using saxon -------------------
This is my sample data.xml file. I want to transform this to html file.
<entity>
<record>10</record>
<record>15</record>
<record>19</record>
<record>7</record>
<record>4</record>
<record>14</record>
<record>24</record>
<entity>
I want to implement a counter for line-number and want to increment the counter and print the line-number
my expected outputs:
case 1: If record values > 14, then my output should have line-number with value as.
line-num value
1 15
2 19
3 24
case 2 : If record values < 14, then my output should have line-number with value as.
line-num value
1 10
2 7
3 4
My other use case :
<entity>
<record>10</record>
<record>15</record>
<record>19</record>
<record>7</record>
<record>20</record>
<record>14</record>
<record>24</record>
<entity>
<record>30</record>
<record>3</record>
</entity>
</entity>
<entity>
<record>5</record>
<record>17</record>
<record>19</record>
<record>6</record>
<record>70</record>
<record>9</record>
<record>35</record>
<entity>
<record>15</record>
<record>2</record>
</entity>
</entity>
This is my other use case, first <entity> record value > 15 and in second <entity> record value < 10, and my <entity> can grow bigger where i have to show only some record based on condition.
line-num value
1 19
2 20
3 24
4 30
5 5
6 6
7 2

Answer 1

There is no way to use Javascript in Saxon as far as I know.
If you want to use an assignable and changeable variable in Saxon 9 (EE or PE) then you can use
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:saxon="http://saxon.sf.net/"
xmlns:mf="http://example.com/mf"
extension-element-prefixes="saxon"
exclude-result-prefixes="xs saxon mf"
version="2.0">
<xsl:variable name="counter" as="xs:integer" select="0" saxon:assignable="yes"/>
<xsl:function name="mf:incr" as="xs:integer">
<saxon:assign name="counter" select="$counter + 1"/>
<xsl:sequence select="$counter"/>
</xsl:function>
<xsl:function name="mf:decr" as="xs:integer">
<saxon:assign name="counter" select="$counter - 1"/>
<xsl:sequence select="$counter"/>
</xsl:function>
<xsl:template match="/" name="main">
a)<xsl:value-of select="mf:incr()"/>
b)<xsl:value-of select="mf:incr()"/>
c)<xsl:value-of select="mf:decr()"/>
</xsl:template>
</xsl:stylesheet>
See the warnings and notes in http://saxonica.com/html/documentation/extensions/instructions/assign.html however on attempts to introduce side effects. You might want to edit your question to explain your XML input and the desired output and why you think you need such a counter variable, hopefully we can then show a pure XSLT 2.0 solution instead of using an assignable variable.
As for your requirement to process and number certain input elements, the stylesheet
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">
<xsl:output indent="yes"/>
<xsl:template match="entity">
<root>
<xsl:apply-templates select="record[. > 14]"/>
<xsl:apply-templates select="record[. < 14]"/>
</root>
</xsl:template>
<xsl:template match="record">
<xsl:copy>
<line-num>
<xsl:value-of select="position()"/>
</line-num>
<value>
<xsl:value-of select="."/>
</value>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
when run against the input
<entity>
<record>10</record>
<record>15</record>
<record>19</record>
<record>7</record>
<record>4</record>
<record>14</record>
<record>24</record>
</entity>
outputs
<root>
<record>
<line-num>1</line-num>
<value>15</value>
</record>
<record>
<line-num>2</line-num>
<value>19</value>
</record>
<record>
<line-num>3</line-num>
<value>24</value>
</record>
<record>
<line-num>1</line-num>
<value>10</value>
</record>
<record>
<line-num>2</line-num>
<value>7</value>
</record>
<record>
<line-num>3</line-num>
<value>4</value>
</record>
</root>
Other options are using e.g. xsl:number count="entity[. < 14]".
As for your latest requirement, I think you can still handle that using position() as long as you select the elements you want to process, e.g. the stylesheet
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:apply-templates select="/root/entity[1]//record[. > 15], /root/entity[2]//record[. < 10]"/>
</xsl:template>
<xsl:template match="record">
<xsl:value-of select="concat(position(), ' ', ., '
')"/>
</xsl:template>
</xsl:stylesheet>
when applied to the input
<root>
<entity>
<record>10</record>
<record>15</record>
<record>19</record>
<record>7</record>
<record>20</record>
<record>14</record>
<record>24</record>
<entity>
<record>30</record>
<record>3</record>
</entity>
</entity>
<entity>
<record>5</record>
<record>17</record>
<record>19</record>
<record>6</record>
<record>70</record>
<record>9</record>
<record>35</record>
<entity>
<record>15</record>
<record>2</record>
</entity>
</entity>
</root>
outputs (with an XSLT 2.0 processor like Saxon 9)
1 19
2 20
3 24
4 30
5 5
6 6
7 9
8 2

Answer 2

(Responding to the expanded description of the problem)
The key thing to appreciate is that this problem requires sequential processing of the record elements, in document order. This means it can't be achieved in a processor-independent way with xsl:for-each or xsl:apply-templates because these are not guaranteed to process the elements one at a time in order (recent versions of Saxon, for example, will process elements in parallel using multi-threading, and the spec allows this; this makes any attempt to update global variables ineffective).
The classic way to process elements sequentially is using head-tail recursion. Write a template or function that takes the sequence of record elements as a parameter, and the current line number as a second parameter. If the list of records is non-empty, then (a) process the first record in the list, and (b) call yourself recursively to process the rest of the list, passing the new value of the line-number.
It can be a bit mind-blowing to write code in this way the first time you try it, but it soon comes naturally.
In XSLT 3.0 there's a new construct xsl:iterate that looks more like a conventional loop: when you enter the xsl:iterate body you pass initial values for its parameters, and each time you continue to the next iteration of the loop you can set new values for the parameters.

Answer 3

Without javascript, using saxon extension instructions.
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:saxon="http://saxon.sf.net/"
extension-element-prefixes="saxon"
exclude-result-prefixes="saxon">
<xsl:variable name="i" select="0" saxon:assignable="yes"/>
<xsl:template match="/">
a) <xsl:value-of select="$i"/>
<saxon:assign name="i" select="$i+1"/>
b) <xsl:value-of select="$i"/>
<saxon:assign name="i" select="$i+2"/>
c) <xsl:value-of select="$i"/>
<saxon:assign name="i" select="$i+3"/>
d) <xsl:value-of select="$i"/>
</xsl:template>
</xsl:stylesheet>