Conditionally retain - sas

Question

I need to create a new variable, called new_id, which displays the same value for either same id tasks or same location tasks. In this example:
Table 1
id Task location
a Task1 lat1
b Task2 lat2
b Task3 lat1
c Task4 lat3
c Task5 lat4
d Task6 lat5
e Task7 lat5
Table want
id Task Location New_id
a Task1 lat1 a
b Task2 lat2 a
b Task3 lat1 a
c Task4 lat3 c
c Task5 lat4 c
d Task6 lat5 d
e Task7 lat5 d
Task1 and Task3 must have the same new_id because they have the same location.
Task2 and Task3 must have the same new_id because they have the same id.
I tried to use a retain data step. First I sort on location, retain the first.variable, then sort id, retain the first.variable.
proc sort data=table1;
by location;
data table1_1;
set table1;
by location;
retain new_id_temp;
if first.location then new_id_temp =id;
new_id=new_id_temp;
run;
proc sort data=table1_1;
by id;
data table1_2;
set table1_1;
by id;
retain id_temp;
if first.id then id_temp=id;
new_id=id_temp;
run;
Based on the above code, I still got two different new_id and proc sort takes lots time if the datasets are large.
Can anyone help?

Answer 1

Your issue here is that you didn't update the second datastep to use new_id as the source for the retained ID, so it's using b not a.
data table1_2;
set table1_1;
by id;
retain id_temp;
if first.id then
id_temp=new_id;
new_id_fin=id_temp;
run;
I'm not sure this is really an effective way to solve your problem generally, but it should give you the results you want. You might want to search around the site (or the web) for other ways to solve this problem, as it's a well understood but complex issue.

Answer 2

/To help you understand the algorithm, I print intermediate results/
%let print_diagnostics = 1; * 0 : no diagnostics 1 : diagnostics *;
/Read in the example, extended with extra data/
options mprint;
title read input data;
data table1;
input id $ Task $ location $;
datalines;
a Task01 lat1
b Task02 lat2
b Tas0k3 lat1
b Task04 lat0
c Task05 lat3
c Task06 lat4
d Task07 lat5
e Task08 lat5
f Task09 lat4
f Task10 lat6
g Task11 lat6
g Task12 lat7
h Task13 lat7
;
proc print;
run;
/The solution needs some iteration, so we need a macro/
%macro re_identify (got, want);
* Initially, we assign id to new_id *;
data &want.;
set &got.;
new_id = id;
run;
* proceed re-assigning ids until stabilised *;
%let pass = 0;
%let proceed = 1;
%do %while (&proceed);
/To lookup the smallest new_id already used for an id or location, I use hash tables. For more information, read Data Step Hash Objects as Programming Tools/
* We will construct two hash tables
* one with the smallest new_id for each id and *
* one with the smallest new_id for each location *
* To achieve this, the smallest new_id should come first *;
%let pass = %eval(&pass + 1);
title pass &pass;
proc sort data=&want.;
by new_id;
run;
data
%if &print_diagnostics %then %do;
hash_id(keep=id id_id)
hash_loc(keep=location loc_id)
%end;
&want. (drop=rc loc_id id_id proceed);
/The hash tables have to be loaded only once of course. Mind the declaration of the data variables!/
* Create hash tables with for each id and location
* the smallest new_id used up to now *;
length loc_id id_id $ 1;
if _N_ eq 1 then do;
dcl hash h_id (dataset: "&want.(rename=(new_id=id_id))");
h_id.defineKey('id');
h_id.definedata('id_id','id');
h_id.defineDone();
dcl hash h_loc (dataset: "&want.(rename=(new_id=loc_id))");
h_loc.defineKey('location');
h_loc.definedata('loc_id','location');
h_loc.defineDone();
* Unless we have to lower the new id for any id or location,
* we can stop after this pass *;
proceed = 0;
end;
retain proceed;
* Read in the data *;
set &want. end=last;
* If there is a task with the same id or location
* with a smaller new_id, lower the new_id for this task *;
rc = h_id.find() + h_loc.find();
if rc then put 'WARNING: location not found' _all_;
if id_id lt new_id then new_id = id_id;
if loc_id lt new_id then new_id = loc_id;
output &want.;
* If we lowered the new_id,
* adapt the hash table
* and proceed after this pass *;
if id_id gt new_id then do;
id_id = new_id;
h_id.replace();
proceed = 1;
end;
if loc_id gt new_id then do;
loc_id = new_id;
h_loc.replace();
proceed = 1;
end;
/Adapting the hashtables with the replace statement is optional but can drastically reduce the number of passes./
* transfer the the decision to proceed
* from a data step variable to a macro variable *;
if last then call symput ('proceed', proceed);
%if &print_diagnostics %then %do;
if last then do;
dcl hiter i_id ('h_id') ;
dcl hiter i_loc ('h_loc') ;
do rc = i_id.first () by 0 while ( rc = 0 ) ;
output hash_id;
rc = i_id.next () ;
end;
do rc = i_loc.first () by 0 while ( rc = 0 ) ;
output hash_loc;
rc = i_loc.next () ;
end;
put "NOTE: after pass &pass." proceed=;
end;
%end;
run;
%if &print_diagnostics %then %do;
* Print intermediate results *;
title2 new id assigned to task; proc print data=&want.; run;
title2 new id assigned to id; proc print data=hash_id; run;
title2 new id assigned to location; proc print data=hash_loc; run;
%end;
%end;
%mend;
%re_identify(table1, table_want);
/And finally write out the report./
* sort in task order and print the final results *;
title final result;
proc sort data=table_want;
by Task;
proc print;
run;
/*
*/

Answer 3

This should give you the results you expect, with a caveat: If you were to add a Task8 having id F and location lat1, you'd need a more refined algorithm with 2 or more passes. But this solution will work fine as long as your id's and locations progress in a way that elements sharing common id's and/or locations are placed after one another.
Generate Sample Dataset
data tasks;
input id $ Task $ location $;
datalines;
a Task1 lat1
b Task2 lat2
b Task3 lat1
c Task4 lat3
c Task5 lat4
d Task6 lat5
e Task7 lat5
;
Generate all Possible Combinations using PROC FREQ
proc freq data=tasks;
table id * task * location / out=combinations (drop=percent count);
run;
Calculate New ID's Based on Your Criteria
data newIDs;
set combinations;
length prev_id $ 1
newID $ 1
prev_location $ 4;
retain newID prev_id prev_location;
* First scenario - first row;
if _N_ = 1 then do;
put _N_= "First scenario - first row";
newID = id;
output;
prev_id = id;
prev_location = location;
end;
* Second scenario - some redundancy between 2 rows;
else if id = prev_id or prev_location=location then do;
put _N_= "Second Scenario - some redundancy";
output;
prev_id = id;
prev_location = location;
end;
* Third scenario - no redundancy;
else do;
put _N_= "Third scenario - no redundancy";
newID = id;
output;
prev_id = id;
prev_location = location;
end;
keep id task location newID;
run;
Merge the Tasks Dataset to the newIDs Dataset
proc sql;
create table tasks_update as
select t.id
,i.newID
,t.Task
,t.location
from tasks as t
left join newIDs as i
on t.id = i.id
and t.task = i.task
and t.location = i.location
order by id;
quit;
Results
id newID Task location
a a Task1 lat1
b a Task2 lat2
b a Task3 lat1
c c Task4 lat3
c c Task5 lat4
d d Task6 lat5
e d Task7 lat5