In SAS, find mean value of all other observations in groups - sas

Question

I am trying to find the mean value of all other observations in the same group.
My data is like
Value Name Group Mean_all_other
544 Pete 1 ....
997 Sara 1 ....
772 Tom 1 ....
725 Tris 2 ....
872 Lulu 2 ....
434 Mica 2 ....
728 Tina 2 ....
827 Bo 3 ....
322 Zu 3 ....
..... ... ... ...
I know that proc means can give you the mean value within groups.
But here I want o create the Mean value of all other in the same group.
In this case, Pete under Mean_all_other will show 884.5, which equals to (997+772)/2.
And Sara= (544+772)/2=658; Tris=(872+434+728)/3=678
Anyone has any idea ?

Answer 1

Consider a proc sql solution using a subquery to average same Group for each row and conditioning out the current Name. Below query uses SAS's not equal operator ^= and mean() function which in regular SQL would use the <> operator and avg() -both still compliant in SAS).
proc sql;
create table NewTable as
select * from
(select main.Value, main.Name, main.Group,
(select mean(sub.Value)
from CurrentTable sub
where sub.Group = main.Group
and sub.Name ^= main.Name) As Mean_all_other
from CurrentTable as main)
quit;
* Value Name Group Mean_all_other
* 544 Pete 1 884.5
* 997 Sara 1 658
* 772 Tom 1 770.5
* 725 Tris 2 678
* 872 Lulu 2 629
* 434 Mica 2 775
* 728 Tina 2 677
* 827 Bo 3 322
* 322 Zu 3 827

Answer 2

Once you have the mean for each whole group, the case-deleted mean for each observation is much easier to calculate. I'd suggest doing this via double DOW loop:
data have;
input Value Name $ Group;
cards;
544 Pete 1
997 Sara 1
772 Tom 1
725 Tris 2
872 Lulu 2
434 Mica 2
728 Tina 2
827 Bo 3
322 Zu 3
;
run;
data want;
do _N_ = 1 by 1 until(last.group);
set have;
by group;
value_sum = sum(value_sum,value);
value_count = sum(value_count,1);
end;
do _N_ = 1 to _N_;
set have;
mean_all_other = (value_sum - value)/(value_count - 1);
output;
end;
drop value_:;
run;

Answer 3

PROC SQL will happily remerge the summary statistics for you. Note that this syntax probably will not work in other SQL implementations, but works fine in SAS. You can use the DIVIDE function to avoid dividing by zero for groups with only one member.
create table want as
select *
, divide(sum(value) - value, n(value) - 1) as mean_all_other
from have
group by group
;
For other SQL implementations you will need to re-merge the aggregate results yourself.
create table want as
select a.*
, divide(b.sum_value - a.value, b.n_value - 1) as mean_all_other
from have a
, (select group,sum(value) as sum_value,n(value) as n_value
from have
group by group
) b
where a.group = b.group
;
If the value of VALUE could be missing then you need to add a CASE statement to handle those cases.
create table want as
select *
, case when (missing(value)) then mean(value)
else divide(sum(value) - value, n(value) - 1)
end as mean_all_other
from have
group by group
;