XSL Apply template to parameter - xslt

Question

I have the following template which slashes apostrophes:
<xsl:template name="replace">
<xsl:param name="pText"/>
<xsl:param name="pTarget" select='"&apos;"'/>
<xsl:param name="pReplacement" select='"\&apos;"'/>
<xsl:if test="$pText">
<xsl:value-of select='substring-before(concat($pText,$pTarget),$pTarget)'/>
<xsl:if test='contains($pText, $pTarget)'>
<xsl:value-of select="$pReplacement"/>
</xsl:if>
<xsl:call-template name="replace">
<xsl:with-param name="pText" select='substring-after($pText, $pTarget)'/>
<xsl:with-param name="pTarget" select="$pTarget"/>
<xsl:with-param name="pReplacement" select="$pReplacement"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
And then I have the following template which produces share code
<xsl:template name="pageshare">
<xsl:param name="url"/>
<xsl:param name="text"/>
<xsl:call-template name="replace"><xsl:with-param name="pText" select="$text"/></xsl:call-template>
<div class="extpageshare">
<div class="social_icon gplus" onclick="shareSocial('google','{$text}','{$url}')"></div>
<div class="social_icon twitter" onclick="shareSocial('twitter','{$text}','{$url}')"></div>
<div class="social_icon facebook" onclick="shareSocial('facebookshare','{$text}','{$url}')"></div>
<div class="social_icon pinterest" onclick="shareSocial('pinterest','{$text}','{$url}')"></div>
<div class="social_icon email" onclick="shareSocial('email','{$text}','{$url}')"></div>
</div>
</xsl:template>
I'm trying to apply the slashes function in the $text parameter so it can be escaped. I tried calling it in the share code dialog but I dont think Im doing it correctly.
Thanks for the help.

Answer 1

It is difficult to answer your question without having a Minimal, Complete, and Verifiable example to work with. I guess you want to do:
<xsl:template name="pageshare">
<xsl:param name="url"/>
<xsl:param name="text"/>
<xsl:variable name="escaped-text">
<xsl:call-template name="replace">
<xsl:with-param name="pText" select="$text"/>
</xsl:call-template>
</xsl:variable>
<div class="extpageshare">
<div class="social_icon gplus" onclick="shareSocial('google','{$escaped-text}','{$url}')"></div>
<div class="social_icon twitter" onclick="shareSocial('twitter','{$escaped-text}','{$url}')"></div>
<div class="social_icon facebook" onclick="shareSocial('facebookshare','{$escaped-text}','{$url}')"></div>
<div class="social_icon pinterest" onclick="shareSocial('pinterest','{$escaped-text}','{$url}')"></div>
<div class="social_icon email" onclick="shareSocial('email','{$escaped-text}','{$url}')"></div>
</div>
</xsl:template>