Flattening a file while preserving duplicate contents - sas

Question

I want to flatten a file to consolidate the variable contents for any occurrence of an ID into one record. Consider the example below...
I have:
ID Date Color Letter
1012 01/23 Red X
1012 10/17 Blu F
1012 07/28 Red N
1012 04/09 Ylw G
1392 04/12 Ylw P
1392 03/11 Blu A
1001 03/11 Blu E
I want:
ID Date1 Date2 Date3 Date4 Clr1 Clr2 Clr3 Clr4 Ltr1 Ltr2 Ltr3 Ltr4
1012 01/23 10/17 07/28 04/09 Red Blu Red Ylw X F N G
1392 04/12 03/11 . . Ylw Blu P A
1001 03/11 . . . Blu E
What is an efficient way to do this?

Answer 1

This works well if you have 100 or less obs per group(id). It works to flop both character and numeric variables at the same time. If you wanted preserve the original order for ID you can add the PROC statement option ORDER=DATA.
data tall;
input (ID Date Color Letter)($);
cards;
1012 01/23 Red X
1012 10/17 Blu F
1012 07/28 Red N
1012 04/09 Ylw G
1392 04/12 Ylw P
1392 03/11 Blu A
1001 03/11 Blu E
;;;;
run;
proc sql noprint;
select max(obs) into :obs
from (select count(*) as obs from tall group by id);
quit;
%put NOTE: &=obs;
proc summary data=tall nway;
class id;
output out=wide(drop=_: id_:) idgroup(out[&obs](_all_)=);
run;

Answer 2

I currently do this by transposing every variable (in a macro when there are more than a few), then merging the resulting datasets (that just contain IDs and the transposed variable of choice) together.
Transposing:
%macro flattener(minids= , fix= , trnvar= );
proc transpose data=have out=&minids prefix=&fix;
by ID;
var &trnvar;
run;
%mend flattener;
%flattener(minids=datDS, fix=Date, trnvar=Date );
%flattener(minids=clrDS, fix=Clr , trnvar=Color );
%flattener(minids=ltrDS, fix=Ltr , trnvar=Letter);
Merging the result:
data ostudentflat;
merge datDS (drop=_NAME_ _LABEL_)
clrDS (drop=_NAME_ _LABEL_)
ltrDS (drop=_NAME_ _LABEL_);
by ID;
run;
I feel like there has to be an easier and faster way to do this, but it gets the job done.