proc report spanning header color - sas

Question

Data set in contains 4 columns col1-col4. I'm trying to create an output which separates 4 columns into two parts.
In the below code, by adding a fake variable blank, I can add one empty column between Part A and Part B.
options missing='';
proc report data=in missing
style(header)=[background=steelblue];
column ('Part A' col1 col2) blank ('Part B' col3 col4);
define blank/computed ' ' style=[background=white];
define col1 / display style[background=tan];
...
compute blank;
blank = .;
call define(_col_,'style','style={background=white borderbottomcolor=white}');
endcomp;
run;
The problem is I need
two different colors for spanning headers and the "original" headers.
the column between two spanning headers should be all white.
But the code is not able to the achieve 2nd purpose.
Current output looks like
1st row ------ Part A Part B (steelblue for entire row)
2nd row ------ col1 col2 col3 col4 (col1-col4 are tan, the column between col2 and col3 and white)
But the desired output is
1st row ------ Part A Part B (steelblue for Part A & B, but the column between them should be white)
2nd row ------ col1 col2 col3 col4 (col1-col4 are tan, the column between col2 and col3 and white)
I found this post but I can't even replicate Cynthia' output. The proc format seems doesn't work.
Proc Report - Coloring for Spanning Headers
This is fairly easy in excel - just insert a new empty column and no fill that column. How can I do this in SAS?

Answer 1

You don't mention ODS destination. This works for HTML and PDF(sort of).
I think the key assuming it actually does what you want is the use of 'a0'x the ascii non-breaking space. But this is not fully tested.
title;
options missing='';
proc format;
value $color
'a0'x = 'white'
other='steelblue'
;
proc report data=sashelp.class missing
style(header)=[background=$color. borderbottomcolor=$color.];
column ('Part A' name sex) ('a0'x blank) ('Part B' age weight height);
define _all_ / display style=[background=tan];
define blank / computed 'a0'x
style=[background=white borderbottomcolor=white]
style(header)=[background=white borderbottomcolor=white];
compute blank / char length=1;
blank = ' ';
call define(_col_,'style','style={background=white borderbottomcolor=white}');
endcomp;
run;

Answer 2

The code Cynthia published contains syntax errors (titles inside the proc report + missing ; on the style(header) lines).
With fixes, this works for me (SAS 9.3 AIX) :
proc format;
value $color
'REPORT' = '#9999FF'
'Australia' = '#FF6600'
'States' = 'pink'
'Wombat' = 'lightgreen'
other = 'lightblue';
value $altclr
'REPORT' = '#9999FF'
'Australia' = '#FF6600'
'States', 'Height', 'Weight' = 'pink'
'Wombat', 'Name', 'Age', 'Sex' = 'lightgreen'
other = 'lightblue';
run;
ods listing close;
ods tagsets.excelxp file = "%SYSFUNC(pathname(work))./Test.xml"
options ( embedded_titles='yes') style = sansprinter;
title 'All Headers Different Colors Based on Formats';
proc report data = sashelp.class(obs=3) nowd
style(header) = { background = $color. font_size= 10pt };
column ('REPORT'('Australia' ('Wombat' name age sex )('States' height weight)));
run;
title 'Some Headers Same Colors Based on Formats (one header diff)';
proc report data = sashelp.class(obs=3) nowd
style(header) = { background = $altclr. font_size= 10pt };
column ('REPORT'('Australia' ('Wombat' name age sex )('States' height weight)));
define name / 'Name';
define age / 'Age';
define sex / 'Sex';
define height / 'Height';
define weight / 'Weight' style(header)={background=lightyellow};
run;
ods _all_ close;