How to dynamically set the put n*"_" for SAS - sas

Question

Tech: SAS 9.3
Currently working in SAS with a programming background vs a BI background.
Also running SAS from a scheduler, and not using EG or any SAS product to run my sas programs
This is what I want to see in my log file:
==================================================================
========================SAS Program Name==========================
==================================================================
Need to do this dynamically so that I can hand off the bit to our contractors to use so we have unified logs, instead of hardcoding it in each of the 500+ sas programs they're creating and modifying.
This is as far as I got
data _null_;
LL=%scan(%sysfunc(getoption(linesize,KEYWORD)),2,"=");
put 132*'=';
put "&progName";
put 132*'=';
run;
What I would is something that looks like this:
data _null_;
LL=%scan(%sysfunc(getoption(linesize,KEYWORD)),2,"=");
padding = (LL - %length("&progName"))/2;
padding = round(padding,1);
put LL*'=';
put padding*'=' "&progName" padding*'=';
put LL*'=';
run;
Is this possible using the put command?

Answer 1

34 %let progname=SAS Program Name.sas;
35 data _null_;
36 LL=input(getoption('linesize'),f8.);
37 put #;
38 _file_ = repeat('=',ll-1);
39 put;
40 progname=translate("&progname",'ff'x,' ');
41 put progname $varying256.-c ll #;
42 _file_ = translate(_file_,'=',' ',' ','ff'x);
43 put ;
44 _file_ = repeat('=',ll-1);
45 put;
46 run;
====================================================================================================================================
========================================================SAS Program Name.sas========================================================
====================================================================================================================================
You could make it a stored program... Update I changed double quoted macro variable reference to SYMGET in the stored version. Otherwise it would only print the program when it was compiled.
%let progname=SAS Program Name.sas;
data _null_ / pgm=work.banner;
LL=input(getoption('linesize'),f8.);
progname=translate(symget('progname'),'ff'x,' ');
put #;
_file_ = repeat('=',ll-1); put;
put progname $varying256.-c ll #;
_file_ = translate(_file_,'=',' ',' ','ff'x); put ;
_file_ = repeat('=',ll-1); put;
run;
data pgm=work.banner;
run;

Answer 2

This can be solved with simple math. If you ever took a typing class using a real typewriter then you may remember how to center titles on the paper.
In this case, I determine how many equals I need to pad the program name by subtracting the length of the program name from the line length. Then divide that number in half to determine how many before and after the program name. The cats function concatenates the equals string before and after the program name. Simple as that.
options linesize=65;
%let progname = My SAS Program;
data _null_;
ll = input(getoption('linesize'), 5.);
put #;
_file_ = repeat('=', ll-1);
put;
equals = repeat('=', (ll-length(strip("&progname"))-1)/2);
_file_ = cats(equals, "&progname", equals);
put;
_file_ = repeat('=', ll-1);
put;
run;
The output in the log:
=================================================================
==========================My SAS Program=========================
=================================================================