Hue shift shader breaks alpha - opengl

Question

I am using cocos2dx. I have a Sprite which is set with a custom shader like this:
boss_1 = Sprite::createWithSpriteFrameName("Zombies/normal/0_0_0.png");
boss_1->setPosition(boss_1->getContentSize()/2.0f);
boss_1->setBlendFunc(cocos2d::BlendFunc::ALPHA_NON_PREMULTIPLIED);
boss_1->setGLProgramState(boss_1_state);
I have the following shader:
vec3 hueAdjust(vec3 color, float hueAdjust)
{
const vec3 kRGBToYPrime = vec3 (0.299, 0.587, 0.114);
const vec3 kRGBToI = vec3 (0.596, -0.275, -0.321);
const vec3 kRGBToQ = vec3 (0.212, -0.523, 0.311);
const vec3 kYIQToR = vec3 (1.0, 0.956, 0.621);
const vec3 kYIQToG = vec3 (1.0, -0.272, -0.647);
const vec3 kYIQToB = vec3 (1.0, -1.107, 1.704);
// Convert to YIQ
float YPrime = dot (color, kRGBToYPrime);
float I = dot (color, kRGBToI);
float Q = dot (color, kRGBToQ);
// Calculate the hue and chroma
float hue = atan (Q, I);
float chroma = sqrt (I * I + Q * Q);
// Make the user's adjustments
hue += hueAdjust;
// Convert back to YIQ
Q = chroma * sin (hue);
I = chroma * cos (hue);
// Convert back to RGB
vec3 yIQ = vec3 (YPrime, I, Q);
color.r = dot (yIQ, kYIQToR);
color.g = dot (yIQ, kYIQToG);
color.b = dot (yIQ, kYIQToB);
// Save the result
return color;
}
void main()
{
vec4 v_orColor = v_fragmentColor * texture2D(CC_Texture0, v_texCoord);
// Hue
vec3 hueAdjustedColor = hueAdjust(v_orColor.rgb, hue_value);
gl_FragColor = vec4(hueAdjustedColor, v_orColor.a);
}
But the alpha seems to get lost and the sprite is rendered with a black background. (Although the hue shift works perfectly, since i can test it with a slider)
This only happens with the hueAdjust function. If I use this other function to change contrast/saturation/brightness, the alpha is preserved perfectly:
vec3 ContrastSaturationBrightness(vec3 color, float brt, float sat, float con)
{
// Increase or decrease these values to adjust r, g and b color channels seperately
const float AvgLumR = 0.5;
const float AvgLumG = 0.5;
const float AvgLumB = 0.5;
const vec3 LumCoeff = vec3(0.2125, 0.7154, 0.0721);
vec3 AvgLumin = vec3(AvgLumR, AvgLumG, AvgLumB);
vec3 brtColor = color * brt;
vec3 intensity = vec3(dot(brtColor, LumCoeff));
vec3 satColor = mix(intensity, brtColor, sat);
vec3 conColor = mix(AvgLumin, satColor, con);
return conColor;
}

Answer 1

It seems like the algorithm in hueAdjust outputs negative colors or NaNs...
I got it working by replacing this line:
vec3 hueAdjustedColor = hueAdjust(v_orColor.rgb, hue_value);
with this one:
vec3 hueAdjustedColor = max(hueAdjust(v_orColor.rgb, hue_value), 0.0);
BTW, algorithm seems to be overcomplicated. Why do you converting colors like this RGB -> YIQ -> HSV -> YIQ -> RGB? You can convert RGB directly to HSV and vice versa without intermediate YIQ stage. Here is fast branchless algorithm for this: http://lolengine.net/blog/2013/07/27/rgb-to-hsv-in-glsl
Hope, it helps :)