Fortran-- reading columns with specific time stamps - fortran

Question

I have this data set and I would like to read it using Fortran and apply a few operations . I have presented the data set below. Here's a short description of the data set. The data set starts of with a time stamp and the subsequent lines (around 60 or 120)are the data points recorded at that time, which is again followed by a time stamp and data and so on so forth. Each file has around 30 observations with 15 different time stamps(i.e two adjacent observations have the same time stamps). I now want to read this file and perform operations such as addition or subtraction of columns on the data points with the same time stamps.
Here the '6:31: 5', '6:27: 9' are the time stamps followed by the data.
Please help as I am unable to figure out a way to do this.
Thank you very much.

Answer 1

Your question leaves a lot of ambiguity. The way I understand it is that you want to read a file where the contents of a line might be one of two different things: a value, or a time stamp.
And you don't know which one it is before you read it.
The best way, I think, is to first read the line into a string.
character(len=20) :: line
read(1001, '(A)') line
Then, based on the first character in that string, you can deduce which one it is.
if (line(1:1) == "'") then
! It's a time stamp
else
! It's a new value
end if
If it's a value, you can read it straight out of the line variable:
read(line, *) val
Reading the time stamp is more complicated, because I don't quite know where the colons are inside it. If the hours are all single digits, you could get away with something like this:
read(line, '(X, I1, X, I2, X, I2)') hour, minute, second
But because there are hours that can't be written with a single digit, I rather doubt that.
So I suggest that you create a subroutine that uses the INDEX function to locate the colons, and then slice the line to read each value separately.
hm = index(line, ':', back=.FALSE.) ! hour-minute separator
ms = index(line, ':', back=.TRUE.) ! minute-second separator
read(line(2:hm-1), *) hour
read(line(hm+1:ms-1), *) minute
read(line(ms+1:), *) second
All put together:
program timestamp
implicit none
integer, parameter :: runit = 1001
integer :: io_err
character(len=20) :: line
real :: val
integer :: hour, minute, second
open(unit=runit, file='data.txt', action='READ', status='OLD', iostat=io_err)
if (io_err /= 0) then
write(*, *) "Unable to open file"
stop 1
end if
do
read(runit, '(A)', iostat=io_err) line
if (io_err == -1) then
write(*, *) "End of file"
exit
end if
if (line(1:1) == "'") then
call read_timestamp(line, hour, minute, second)
write(*, '(A, 2(I2.2, ":"), I2.2)') "New timestamp: ", hour, minute, second
else
read(line, *) val
write(*, *) "Data: ", val
end if
end do
close(runit)
contains
subroutine read_timestamp(line, hour, minute, second)
implicit none
character(len=*), intent(in) :: line
integer, intent(out) :: hour, minute, second
integer :: hm, ms ! Indices of separators
hm = index(line, ':', back=.FALSE.)
ms = index(line, ':', back=.TRUE.)
read(line(2:hm-1), *) hour
read(line(hm+1:ms-1), *) minute
read(line(ms+1:), *) second
return
end subroutine read_timestamp
end program timestamp