Strip file name of non-alphanumeric characters - regex

Question

How can I rename a file to a file name stripped of all other characters except letters and numbers?
For example:
It's_A Brand (New) #Year,,2016!.txt renamed to ItsABrandNewYear2016.txt
Is it possible to do this with Windows batch?

Answer 1

Save the code below as a Batch file (with .BAT extension):
#if (#CodeSection == #Batch) #then
#echo off
setlocal
set "oldname=It's_A Brand (New) #Year,,2016!.txt"
for %%f in ("%oldname%") do (
for /F %%a in ('cscript //nologo //E:JScript "%~F0" "%%~Nf"') do ECHO ren "%%~f" "%%a%%~Xf"
)
goto :EOF
#end
// JScript section
WScript.Stdout.WriteLine(WScript.Arguments(0).replace(/[\W_]/g,""));
Output:
ren "It's_A Brand (New) #Year,,2016!.txt" "ItsABrandNewYear2016.txt"

Answer 2

#ECHO OFF
SETLOCAL
set "filename=It's_A Br#$^[-+={;}]a.nd & (New) #Year,,2016!.txt"
SET "newname="
FOR %%a IN ("%filename%") DO CALL :strip "%%~na" "%%~xa"
ECHO RENAME "%filename%" to "%newname%"
GOTO :EOF
:strip
SET "string=%~1"
IF NOT DEFINED string SET "newname=%newname:~0,-1%"&GOTO :EOF
:striploop
SET "char=%string:~0,1%"
ECHO "%char%"|FINDSTR /i /r "[a-z] [0-9]" >NUL
IF NOT ERRORLEVEL 1 SET "newname=%newname%%char%"
SET "string=%string:~1%"
IF DEFINED string GOTO striploop
SHIFT
SET "newname=%newname%."
GOTO strip
Reasonably straight-forward. Note that only the last dot in the name (if any) is preserved.

Answer 3

I have written a hybrid batch/JScript utility called JREN.BAT that provides regular expression renaming directly from the command line, without any additional scripting required. It is pure script that runs natively on any Windows machine from XP onward.
The solution is similar to Aacini's, except the find/replace is applied to the entire name, so the regular expression must be a bit more complex to preserve the extension dot.
jren "[^a-z0-9.]|\.(?!txt$)" "" /i /fm "It's_A Brand (New) #Year,,2016!.txt"
The solution can easily be made to remove all non-alphanumeric characters from all file names in the current directory, except it preserves the extension dots.
jren "[^a-z0-9.]|\.(?![^.]+$)" "" /i
Note that JREN is a batch script, so you must use call jren if you use the command within another batch script.