XPath Recursive Descent behaves differently between match and select - xslt

Question

Info
Why is there different behaviour of Recursive Descent operator between
● template's match attribute where it is ignored and only children are selected ignoring their descendants
● for-each's select attribute where it works properly
Two examples of test.xsl are given which both operate on the following test.xml.
test.xml
<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="test.xsl"?>
<people>
<person id="(1)">
<name>Lucy</name>
</person>
<class>
<person id="(2)">
<name>David</name>
<person id="(21)">
<name>David</name>
</person>
</person>
</class>
</people>
match="//person"
In this example we are trying to use match="//person" to select ALL
person elements from document which doesn't work. Instead of
selecting ALL root descendants person elements, person elements which
are inside other person elements (like id="(21)") are not
included.
test.xsl
<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="text()"/>
<xsl:template match="//person">
<xsl:value-of select="#id"/>
</xsl:template>
</xsl:stylesheet>
output.xml
(1)(2)
select="//person"
In this example we are using select="//person" to select ALL person
elements from the document. This will properly select ALL root
descendants person elements including id="(21)". Value of
match="class" is irrelevant since select="//person" uses absolute
path.
test.xsl
<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="text()"/>
<xsl:template match="class">
<xsl:for-each select="//person">
<xsl:value-of select="#id"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
output.xml
(1)(2)(21)

Answer 1

There is a difference between a match pattern and a select expression. A match pattern does not select anything - it is only used to see if the current node matches the pattern. For this reason, the match pattern match="//person" is the same as match="person".
If a node never gets to be the current node (i.e. templates are not applied to it), then it doesn't matter if it matches any template's match pattern or not. This is shown in your first example: the built-in template rules are applied recursively until the <person id="(2)"> node is encountered; this matches a pattern of a more specific template - but that template has no instructions to apply templates to any of its descendants, so the chain breaks at this point, and the node <person id="(21)"> is never examined to see if there is a template matching it.

Answer 2

Well a template with a match on its own does not cause any processing and your template with
<xsl:template match="//person">
<xsl:value-of select="#id"/>
</xsl:template>
outputs the id attribute and does no further processing. So you will need to make sure you have an apply-templates e.g.
<xsl:template match="//person">
<xsl:value-of select="#id"/>
<xsl:apply-templates/>
</xsl:template>
or you will need a template like
<xsl:template match="/">
<xsl:apply-templates select="//person"/>
</xsl:template>
that makes sure all person elements are processed.
Also note that a match="//person" is the same as match="person" so all you need is
<xsl:template match="/">
<xsl:apply-templates select="//person"/>
</xsl:template>
and
<xsl:template match="person">
<xsl:value-of select="#id"/>
</xsl:template>