aggregate by column value and paste row values together in SAS - sas

Question

I have a data set that looks like:
Have:
data have;
input a b c d e f g h ;
datalines;
1 0 0 0 0 0 1 0
0 0 1 0 1 0 0 0
0 0 0 1 0 1 0 0
0 1 0 0 0 0 0 1
;
run;
The columns a, b, c and d are four options to the question 1 on a 4-point scale. The value "1" in obs1 column A signifies that respondent has chosen option A for that question which signifies 4 on the 4 point scale.
a = 4, b = 3, c = 2 and d = 1.
The next question's options are e, f, g and h. The respondent has chosen option g which is 2 on the 4 point scale. e = 4, f = 3, g = 2 and h = 1.
The data set contains hundreds of columns like this. My idea is to collapse 4 columns into one getting values like : "1000", "0100", "0010", "0001" and then converting 1000 = 4, 0100 = 3, 0010 = 2 and 0001 = 1.
I want it to be like :
block col1 col2 col3 col4
1 1000 0100 0010 0001
2 0100 0010 1000 0001
3 1000 0100 1000 0010
I've gotten this far:
proc transpose data = have out = have_t;
run;
data have_t_block;
set have_t;
retain block;
if _n_ = 1 then block = 1;
if mod(_n_/4,1) = 0.25 and _n_ gt 1 then block +1;
run;
Is there a way to concatenate the row values while aggregating by block in SAS? I do this in R, like this:
#Create data
data <- data.frame(a = c(1, 0, 0), b = c(0, 1, 0), c = c(0, 0, 1), d = c(0, 0, 0), e = c(0, 1, 0), f = c(1, 0, 0), g = c(0, 0, 1), h = c(0, 0, 0), i = c(0, 0, 1), j = c(1, 0, 0), k = c(0, 0, 0), l = c(0, 1, 0))
#transpose
data <- data.frame(t(data))
#create a key for each group of 4
data$block <- rep(1:(nrow(data)/4), each = 4)
#convert data to long format and group by key (block) and use paste to concatenate
require(reshape2)
data_melt <- melt(data, id = c("block"))
trial <- data.frame(t(dcast(data_melt, block ~ variable, paste, collapse = "")))

Answer 1

First off, unless you misexplained your data, your transpose didn't help things very much here as there's no particular reason to have this have one column for each respondent - let's just have one column, period. Here's a better way to do this.
data have_t;
set have;
array cols a--h;
do _i = 1 to dim(cols);
value = cols[_i];
output;
end;
keep value; *and an ID I hope?;
run;
Making a dataset 'vertical' (one column) is very easy. Just loop over an array of all of your columns, for each set a common variable to that value, output. Normally i'd keep track of the variable name I was outputting also, but perhaps that's not necessary.
For your main problem, what you'll want to do is use retain, most likely, not dissimilar to how you handle block. Here I just calculate score directly:
data want;
set have_t;
retain score;
counter = mod(_n_,4);
if counter=1 then block+1; *slightly easier version of what you wrote;
if value=1 then score = 5-counter; *first=4, second=3, third=2, fourth=1;
if counter=0 then output;
*We never "clear" score here - to be safer you may want to do that in the if counter=1 block;
run;
If you want the intermediate '0010' or whatever, you can include that as well.
data want;
set have_t;
retain score int_Value;
length int_Value $4;
counter = mod(_n_,4);
if counter=1 then block+1; *slightly easier version of what you wrote;
if value=1 then score = 5-counter; *first=4, second=3, third=2, fourth=1;
int_value = cats(int_value,value);
if counter=0 then do;
output;
int_value=' '; *have to clear this every 4;
score=.; *here we might as well clear it;
end;
run;

Answer 2

If I understood your question correctly,try this:
data want;
do i=1 by 1 until(last.block);
set have_t_block;
array var $4. var1-var4;
array col col1-col4;
length var1-var4 $4.;
by block notsorted;
do over var;
var=cats(var,col);
end;
if last.block then output;
end;
keep var: block;
run;