Match multiple line string in Perl - regex

Question

I'm new to Perl and I was wondering if someone can help me.
I have an input like this:
a,b,
c,d,e,f,g,h,
i,j,q // Letras
I'm trying to get the letters before // separately and then print them between {} separated by :.
I tried with this RE ([\w,;:\s\t]*)(\n|\/\/)/m and I could get in $1 all letters for each line (as a string including separators) but not what I want.
I need to match that pattern more than one time in the same file so I was using /g.
Edit:
Here is my code block:
while ( <> ) {
if ( /([\w,;:\s\t]*)(\n|\/\/)/m ) {
print "$1\n";
}
}

Answer 1

/m is for using ^, and $ to match by line in a string with multiple lines.
On the other hand, you are reading the input line by line. You cannot expect to match across lines with a single expression if you only look at one line at a time.
Instead, read by chunks by setting $/ to an appropriate value. If the chunks always end in the exact string "// Letras\n\n", the task is even simpler.
#!/usr/bin/env perl
use strict;
use warnings;
local $/ = '//';
while (my $chunk = <DATA>) {
chomp $chunk;
my #fields = ($chunk =~ /([a-z])[, ]/g);
next unless #fields;
printf "{%s}\n", join(':', #fields);
}
__DATA__
a,b,
c,d,e,f,g,h,
i,j,q // Letras
a,b,
c,d,e,f,g,h,
i,j,q // Metras
Output:
{a:b:c:d:e:f:g:h:i:j:q}
{a:b:c:d:e:f:g:h:i:j:q}
You can also use File::Stream:
#!/usr/bin/env perl
use strict;
use warnings;
use File::Stream;
my $stream = File::Stream->new(
\*DATA,
separator => qr{ (?: \s+ // [^\n]+ ) \n\n }x
);
while (my $chunk = <$stream>) {
$chunk =~ s{ \s+ // .* \z }{}sx;
$chunk =~ s{ ,\n? }{:}gx;
print "{$chunk}\n";
}
__DATA__
a,b,
c,d,e,f,g,h,
i,j,q // Letras
a,b,
c,d,e,f,g,h,
i,j,q // Metras

Answer 2

I think what you're aiming for is to remove comments (denoted by a double slash) from each line, and print it out enclosed by braces, and with a colon : separator instead of commas
First of all you should remove the trailing linefeed character from each line using chomp
Then all you need to remove any trailing comment is s|\s*//.*||. That removes any spaces before the // as well. I'm using a pipe character | as the delimiter so as to avoid having to escape the slashes within the regex pattern. And the data is being processed one line at a time so there no need for the global /g modifier
This program reads from the file specified on the command line, which I've set up to contain the data you show in the question
use strict;
use warnings;
while ( <DATA> ) {
chomp;
s|\s*//.*||;
print "{$_}\n";
}
output
{a,b,}
{c,d,e,f,g,h,}
{i,j,q}
Update
Thanks to Sinan Ünür's solution I notice that you've asked to "print [the letters] between {} separated by :"
This is a modification of the while loop above, which finds all substrings within the current line that don't contain commas, and joins them together again using colons :
while ( <> ) {
chomp;
s|\s*//.*||;
my $values = join ':', /[^,]+/g;
print "{$values}\n";
}
output
{a:b}
{c:d:e:f:g:h}
{i:j:q}
I am sure the true solution is much more simple, but unless you elaborate your question we have to cater for all possibilities

Answer 3

Are you looking to combine the letters on all 3 lines into the output, or convert each line?
In other words, is your desired output
{a:b}
{c:d:e:f:g:h}
{i:j:q}
or
{a:b:c:d:e:f:g:h:i:j:q}
?
If you want the former, Borodin's answer works.
If you want the latter, then you should load the contents into an array, and print it using a join statement. To do that, I've modified Borodin's answer:
while ( <> ) { # read each line
chomp; # remove \n from line
s|\s*//.*||; # remove comment
push #values, ':', /[^,]+/g; # store letters in array
}
my $values = join ':', #values; # convert array to string
print "{$values}\n"; # print the results

Answer 4

my $str = "a,b,
c,d,e,f,g,h,
i,j,q // Letras";
$str = join "",map {s/,/:/g ;(split)[0]} split '\n', $str;
print "{$str}";
Sample output
{a:b:c:d:e:f:g:h:i:j:q}
I am considering a string with multilines separated by newline character.
join "",map {s/,/:/g ;(split)[0]} split '\n', $str
This is evaluated from right to left.
Split with \n on $str produces 3 elements which is input for map.
(split)[0] : default delimiter for split is whitespace. so each element is split for whitespace and 0th element is only considered discarding others.
Ex (split)[0] for i,j,q // Letras produces 3 elements "i,j,q" "//" "Letras" where only element 0 i.e., "i,j,q" is considered.
, is replaced with :
join is used to combine all the resulting elements from map.