How can I delete the last word in the current line, but only if a pattern occurs on the next line? - regex

Question

The contents of the file are
some line DELETE_ME
some line this_is_the_pattern
If the this_is_the_pattern occurs in the next line, then delete the last word (in this case DELETE_ME) in the current line.
How can I do this using sed or awk? My understanding is that sed is more appropriate for this task than awk is, because awk is suitable for operations on data stored tabular format. If my understanding is incorrect, please let me know.

Answer 1

$ awk '/this_is_the_pattern/{sub(/[^[:space:]]+$/, "", last)} NR>1{print last} {last=$0} END{print last}' file
some line
some line this_is_the_pattern
How it works
This script uses a single variable called last which contains the previous line in the file. In summary, if the current line contains the pattern, then the last word is removed from last. Otherwise, last is printed as is.
In detail, taking each command in turn:
/this_is_the_pattern/{sub(/[^[:space:]]+$/, "", last)}
If this line has the pattern, remove the final word from the last line.
NR>1{print last}
For each line after the first line, print the last line.
last=$0
Save the current line in variable last.
END{print last}
Print the last line from the file.

Answer 2

awk 'NR>1 && /this_is_the_pattern/ {print t;}
NR>1 && !/this_is_the_pattern/ {print f;}
{f=$0;$NF="";t=$0}
END{print f}' input-file
Note that this will modify whitespace in any lines in which the last field is removed, squeezing runs of whitespace into a single space.
You could simplify this to:
awk 'NR>1 { print( /this_is_the_pattern/? t:f)}
{f=$0;$NF="";t=$0}
END{print f}' input-file
and you can resolve the squeezed whitespace issue with:
awk 'NR>1 { print( /this_is_the_pattern/? t:f)}
{f=$0;sub(" [^ ]*$","");t=$0}
END{print f}' input-file

Answer 3

You could use tac to cat the file backwards, so that you see the pattern first. Then set a flag and delete the last word on the next line you see. Then at the end, reverse the file through tac back to the original order.
tac file | awk '/this_is_the_pattern/{f=1;print;next} f==1{sub(/ [^ ]+$/, "");print;f=0}' | tac

Answer 4

Use buffer to keep previous line in memory
sed -n 'H;1h;1!{x;/\nPAGE/ s/[^ ]*\(\n\)/\1/;P;s/.*\n//;h;$p;}' YourFile
Use loop but same concept
sed -n ':cycle
N;/\nPAGE/ s/[^ ]*\(\n\)/\1/;P;s/.*\n//;$p;b cycle' YourFile
in both case, it remove last word of previous line also the search pattern is on 2 consecutive lines
work with 2 last read lines, test if pattern on last and delete word if present than print first line, remove it and cycle

Answer 5

The idiomatic awk solution is simply to keep a buffer of the previous line (or N lines in the general case) so you can test the current line and then modify and/or print the buffer accordingly:
$ awk '
NR>1 {
if (/this_is_the_pattern/) {
sub(/[^[:space:]]+$/,"",prev)
}
print prev
}
{ prev = $0 }
END { print prev }
' file
some line
some line this_is_the_pattern