finding the next prime number in pascal - primes

Question

I am trying to find the next prime number after the number the user enters in and i have to do it in pascal . I don't even know what to start with , could anyone help me?
program PRIME;
uses crt;
var
C, N : INTEGER;
const
A=2;
Begin PS:
Writeln ('enter your number' ) ;
Read (N);
begin
Writeln(
readln;
End.

Answer 1

You should declare n-element array of bools (primes values are true), where n is a number entered by user and multiplied by two. Then find all primes up to n using sieve of Eratosthenes algorithm (remove all composite numbers changing their values to false). After that, finding next prime number after entered value will be easy. Indexes of true values are prime numbers.
Try to write your own code and then edit your question if it doesn't work.

Answer 2

Two hints:
if the number entered is < 2 then the next prime is 2.
if the number entered is >= 2 then the next prime is an odd number greater than the number entered and less than twice the number entered (Bertrand's Postulate).
No, we won't write your Pascal code for you.

Answer 3

The first step in solving this problem is figuring out how to do it by hand. From wikipedia:
A simple but slow method of verifying the primality of a given number
n is known as trial division. It consists of testing whether n is a
multiple of any integer between 2 and sqrt{n}.
So if you are given 6, you would first test the number 7 to see if it is prime. You test if 7 is prime by dividing all the integer numbers from 2 to the square root of 7(2.645751311). So you have to only test to see if 7 is divisible by 2. If the user enters 14, you have first test to see if 15 is divisible by any of the integer numbers from 2 to the square root of 15 (3.872983346). So you would test to see if 15 is divisible by 2 or 3.
There are two loops involved. One is adding 1 to the input number repeatedly - that is - if they input 10, you test 11 for primeness, then 12, then 13, then 14, then 15, etc. The other loop is dividing all the integer numbers between 2 and the square root of the current number being checked for primeness. Divide it by 2, is there a remainder? Divide by 3, is there a remainder? Divide by 4, is there a remainder? And so on. Each time you get a division with no remainder you can stop that loop since you know that you have not found a prime and need to increment the value and recalculate your square root and start dividing again.
In Free Pascal it looks like this:
program NextPrimeNumber;
uses
Math;
var
user_input : integer;
next_prime : integer;
function CalculateNextPrimeNumber(value : integer) : integer;
var
next_prime_not_found : boolean = true;
square_root : integer = 0;
i : integer = 0;
remainder : integer = 0;
result : integer = 0;
successful_divisions : integer = 0;
begin
(* loop through the numbers above our value till we find one that
is not divisible *)
while next_prime_not_found do
begin
successful_divisions := 0;
value := value + 1;
square_root := trunc(sqrt(value));
(* try and divide by all the numbers between 2 and the square root of
out current number (square root value truncated
to next lowest integer) *)
for i := 2 to square_root do
begin
DivMod(value,i,result,remainder);
if remainder = 0 then
begin
successful_divisions := successful_divisions + 1;
(* this is a non-prime number, so quit trying more divisions *)
break;
end;
end;
if successful_divisions = 0 then
(* we found a prime so stop looking by setting the value
the while loop is checking to false *)
next_prime_not_found := false;
end;
CalculateNextPrimeNumber := value;
end;
begin
writeln('enter a postive number');
readln(user_input);
next_prime := CalculateNextPrimeNumber(user_input);
writeln('the next prime number after ',user_input,' is ',next_prime);
end.

Answer 4

var a,y,i,k:qword;
f:text;
begin
assign(f,'numere.prime');
reset(f);
while not eof(f) do
begin
readln(f,i);
end;
close(f);
repeat
k:=0;
inc(i);
reset(f);
while not eof(f) do
begin
readln(f,a);
if i mod a = 0 then
begin
inc(k);
break;
end;
end;
close(f);
if k=0 then
begin
append(f);
writeln(f,i);
close(f);
end;
until i=10000000;
end.
This program writes all the prime numbers below 10000000 in a file. Later, you can write a new program that checks if the entered number is in that file. (On the first line of the file is '2')