Stata: break ties in rank of a variable using a second variable - stata

Question

I would like to rank observations in Stata by score1, while breaking ties using score2, as below:
score1 score2 desired_rank
____________________________
99 5 1
99 4 2
89 8 3
80 9 4
80 9 4
78 6 6
I've tried using egen rank, but can't find an option for specifying another variable for tiebreaking.
I've also read this post, but I haven't been able to adapt its solution to my problem very elegantly.
Any recommendations on how to create desired_rank?

Answer 1

One way could be:
clear
set more off
*----- example data -----
input ///
score1 score2 desired_rank
99 4 2
99 5 1
89 8 3
80 9 4
78 6 6
80 9 4
end
list, sep(0)
*----- what you want -----
egen scoreg = group(score1 score2)
egen myrank = rank(scoreg), field
// check
assert desired_rank == myrank
sort myrank
list, sep(0)
The key here is that egen, group() will assign group numbers according to the sort order of the varlist: score1 score2. Then use egen, rank() but with the field option which will rank the highest value as 1 and will not correct ties.

Answer 2

Let's flag here that the question asks for a twist on Stata's default ranking conventions. By default, Stata ranks the lowest value as 1, as is the more common practice in statistics, but here the question asks for the opposite convention, which Stata calls field ranks. That term is intended to evoke field events in athletics such as throwing and jumping in which the highest or longest score is ranked 1.
#Roberto Ferrer's solution is good, but let's work from first principles as an alternative. If we get the observations into the desired sort order, the rank desired is just the observation number, except that if the values in one observation are the same as those in the preceding observation, that rank is used, an exception we apply in cascade.
Here is some code:
clear
input score1 score2 desired_rank
99 5 1
99 4 2
89 8 3
80 9 4
80 9 4
78 6 6
end
gsort -score1 -score2
gen Desired_Rank = _n
replace Desired_Rank = Desired_Rank[_n-1] if score1 == score1[_n-1] & score2 == score2[_n-1]
assert desired_rank == Desired_Rank
Had we wanted lowest values to rank 1, the sorting command would have been
sort score1 score2
This solution gets messier if we want to rank only some observations using if or in; or if there are missing values; or if there are more scores to be used. In all those cases a solution based on egen is cleaner.
This is a good point to emphasise a trick obvious when it's explained:
egen rank1 = rank(mpg)
egen rank2 = rank(-mpg)
Negating a variable flips the ranking order round. The ranks of 2.71828, 3.14159 and 42 are 1, 2, 3; the ranks of -2.71828, -3.14159, -42 are 3, 2, 1. People often miss that the rank() function of egen can be fed an expression, which can easily be more complicated than a single variable name.
Personal note: When writing some ranking code for Stata in 1999, I was surprised to find no hint in the statistical or computing literature of names for different kinds of ranks, so I introduced the terms field and track to the Stata literature. Some years on, the only other term I have noticed is "schoolmaster's rank" for field rank, but that does not seem a better term, for several quite different reasons.