closing box is need to apply when this relevant code is missing - xslt

Question

I have the input xml as follows. In this xml, sometimes, <par class="endboxa"> is missing. But, anyway i need to match this input and output box equally on the output. I mean whenever, the endboxa is missing, then, anyway, i need to do match this. Any help?
input xml
[code]
<par class="startboxa"><inline style="border-bottom-width: 3.0pt; border-bottom-style: solid; border-bottom-color: #ff0000; list-style-type: decimal; "></inline></par>
<par class="para" xml:lang="de"><inline style="list-style-type: decimal; ">Alle Aspekte der Verfügbarkeit und alle Phasen des Servicelebenszyklus sind bei den Service Design Aktivitäten zu berücksichtigen.</inline></par>
<par class="para" xml:lang="de"><inline style="list-style-type: decimal; ">Der Beitrag des Availability Management zu den Design-Aktivitäten ist:</inline></par>
<par class="para" xml:lang="de"><inline style="list-style-type: decimal; ">Können die Verfügbarkeitsanforderungen nicht eingehalten indem geprüft wird, ob eine entsprechend leistungsfähige Technologie in das vorgeschlagene IT-Design implementiert werden kann. Beispiel:</inline></par>
<par class="startboxa"><inline style="border-bottom-width: 3.0pt; border-bottom-style: solid; border-bottom-color: #ff0000; list-style-type: decimal; "></inline></par>
<par class="para" xml:lang="de"><inline style="list-style-type: decimal; font-weight: bold; ">Hinweise und Tipps</inline></par>
<par class="para" xml:lang="de"><inline style="list-style-type: decimal; ">Dokugen werden und in geeignete Governance-Strukturen integriert werden, die auf die Einführung neuer IT Services ausgerichtet sind.</inline></par>
<par class="endboxa"><inline style="list-style-type: decimal; border-top-width: 3.0pt; border-top-style: solid; border-top-color: #ff0000; "></inline></par>
[/code]
My xslt code as of now, I need to updated based on the advise
<xsl:template match="par[#class = 'startboxa']">
<xsl:text disable-output-escaping="yes"><div class="panel"></xsl:text>
</xsl:template>
<xsl:template match="par[#class = 'endboxa']">
<xsl:text disable-output-escaping="yes"></div></xsl:text>
</xsl:template>
output XML [Now I am getting]
[code]
<div class="panel">
<p class="para">Alle Aspekte der Verfügbarkeit und alle Phasen des Servicelebenszyklus sind bei den Service Design Aktivitäten zu berücksichtigen.</inline></p>
<p class="para">Der Beitrag des Availability Management zu den Design-Aktivitäten ist:</inline></p>
<p class="para">Können die Verfügbarkeitsanforderungen nicht eingehalten indem geprüft wird, ob eine entsprechend leistungsfähige Technologie in das vorgeschlagene IT-Design implementiert werden kann. Beispiel:</inline></p>
<div class="panel">
<p class="para">Hinweise und Tipps</inline></p>
<p class="para">Dokugen werden und in geeignete Governance-Strukturen integriert werden, die auf die Einführung neuer IT Services ausgerichtet sind.</inline></p>
</div>
[/code]
Correct output XML[that i need]
[code]
<div class="panel">
<p class="para">Alle Aspekte der Verfügbarkeit und alle Phasen des Servicelebenszyklus sind bei den Service Design Aktivitäten zu berücksichtigen.</inline></p>
<p class="para">Der Beitrag des Availability Management zu den Design-Aktivitäten ist:</inline></p>
<p class="para">Können die Verfügbarkeitsanforderungen nicht eingehalten indem geprüft wird, ob eine entsprechend leistungsfähige Technologie in das vorgeschlagene IT-Design implementiert werden kann. Beispiel:</inline></p>
</div>[`here i need closing tag`]
<div class="panel">
<p class="para">Hinweise und Tipps</inline></p>
<p class="para">Dokugen werden und in geeignete Governance-Strukturen integriert werden, die auf die Einführung neuer IT Services ausgerichtet sind.</inline></p>
</div>
[/code]

Answer 1

You've tagged this as XSLT 2.0, which is good, as you should be able to use xsl:for-each-group here, to group your par elements, starting with the "startboxa" one
<xsl:for-each-group select="par" group-starting-with="par[#class='startboxa']">
With this approach, you don't actually have to worry about whether the 'endboxa' exists or not. Just output a div and output everything within it
<div>
<xsl:apply-templates select="current-group()" />
</div>
This would pick up the "startboxa", and the "endboxa" (if it is exists), so you just need two matching templates to ignore them (unless you did want to output something different for them)
<xsl:template match="par[#class = 'startboxa']" />
<xsl:template match="par[#class = 'endboxa']" />
Try this XSLT. This assumes your current XML is part of a parent element called parent:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output indent="yes"/>
<xsl:template match="parent">
<xsl:for-each-group select="par" group-starting-with="par[#class='startboxa']">
<div>
<xsl:apply-templates select="current-group()" />
</div>
</xsl:for-each-group>
</xsl:template>
<xsl:template match="par[#class = 'para']">
<p><xsl:apply-templates /></p>
</xsl:template>
<xsl:template match="par[#class = 'startboxa']" />
<xsl:template match="par[#class = 'endboxa']" />
</xsl:stylesheet>
EDIT: If you did actually wanted an XSLT 1.0 solution, you can replicate the "group-starting-with" by defining a key that groups the par elements by their first most preceding "startboxa" element
<xsl:key name="par" match="par[not(#class='startboxa')]"
use="generate-id(preceding-sibling::par[#class='startboxa'][1])" />
You then change the xsl:for-each-group to just an xsl:for-each to get the 'starting' element
<xsl:for-each select="par[#class='startboxa']">
Then, to get the elements in the group, you can use the key
<xsl:apply-templates select="key('par', generate-id())" />
The main difference is the key does not actually include the 'startboxa' element itself, so you don't need the extra template to ignore it.
Try this XSLT 1.0
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:key name="par" match="par[not(#class='startboxa')]" use="generate-id(preceding-sibling::par[#class='startboxa'][1])" />
<xsl:template match="parent">
<xsl:for-each select="par[#class='startboxa']">
<div>
<xsl:apply-templates select="key('par', generate-id())" />
</div>
</xsl:for-each>
</xsl:template>
<xsl:template match="par[#class = 'para']">
<p><xsl:apply-templates /></p>
</xsl:template>
<xsl:template match="par[#class = 'endboxa']" />
</xsl:stylesheet>